Initial commit

PKGBUILD and LICENSE mostly copied from the t1utils package, then
adapted. pkgver() adapted from the mkosi-git PKGBUILD.

3 files changed, 88 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..69c8f5df8bab
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,19 @@
+# Generated by mksrcinfo v8
+# Wed Mar 21 22:49:10 UTC 2018
+pkgbase = t1utils-git
+	pkgdesc = A collection of simple Type 1 font manipulation programs
+	pkgver = 1.41.r1.g3f1ddda
+	pkgrel = 1
+	url = http://www.lcdf.org/~eddietwo/type/#t1utils
+	arch = x86_64
+	license = custom
+	depends = glibc
+	provides = t1utils
+	conflicts = t1utils
+	source = git://github.com/kohler/t1utils.git
+	source = LICENSE
+	sha256sums = SKIP
+	sha256sums = fd00d777e6114f1d346978844f19bbec1652641ea40d24c12ec5aac6f3ebc7cb
+
+pkgname = t1utils-git
+
diff --git a/LICENSE b/LICENSE
new file mode 100644
index 000000000000..43f03171f77c
--- /dev/null
+++ b/LICENSE
@@ -0,0 +1,22 @@
+The README file includes the following notices:
+
+   Changes since version 1.2 (c) 1998-2000 Eddie Kohler, under the
+   same redistribution copyright as I. Lee Hetherington's. See below
+   for I. Lee Hetherington's original README from 1992, updated
+   slightly for today's t1utils.
+
+   Eddie Kohler
+   eddietwo@lcs.mit.edu
+
+   Copyright (c) 1992 by I. Lee Hetherington, all rights reserved.
+
+   Permission is hereby granted to use, modify, and distribute this
+   program for any purpose provided this copyright notice and the one
+   below remain intact.
+
+   Note that these tools should not be used to illegally copy type-1
+   font programs.  Typeface design is an intricate art that should be
+   rewarded.
+
+   I. Lee Hetherington
+   ilh@lcs.mit.edu
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..6657ad833d6c
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,47 @@
+# Maintainer: Lucas Werkmeister <mail@lucaswerkmeister.de>
+# Contributor: Evgeniy Alekseev <arcanis at archlinux dot org>
+# Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
+# Contributor: Simo Leone <neotuli@gmail.com>
+
+pkgname=t1utils-git
+reponame=${pkgname%-git}
+pkgver=1.41.r1.g3f1ddda
+pkgrel=1
+pkgdesc='A collection of simple Type 1 font manipulation programs'
+arch=('x86_64')
+url='http://www.lcdf.org/~eddietwo/type/#t1utils'
+license=('custom')
+depends=('glibc')
+provides=('t1utils')
+conflicts=('t1utils')
+source=("git://github.com/kohler/$reponame.git"
+        'LICENSE')
+sha256sums=('SKIP'
+            'fd00d777e6114f1d346978844f19bbec1652641ea40d24c12ec5aac6f3ebc7cb')
+
+pkgver() {
+    cd "$reponame"
+
+    git describe --long --tags | sed '
+        # v1.41-1-g3f1ddda (tag - number of commits - g(it)hash)
+        s/^v//
+        # 1.41-1-g3f1ddda
+        s/\([^-]*-g\)/r\1/
+        # 1.41-r1-g3f1ddda
+        s/-/./g
+        # 1.41.r1.g3f1ddda
+'
+}
+
+build() {
+    cd "$srcdir/$reponame"
+    ./bootstrap.sh
+    ./configure --prefix=/usr
+    make
+}
+
+package() {
+    cd "$srcdir/$reponame"
+    make DESTDIR="$pkgdir" install
+    install -D -m644 "$srcdir/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}