Initial import

2 files changed, 59 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..67fe2a1f06a7
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,23 @@
+pkgbase = tagger-git
+	pkgdesc = Tag your music
+	pkgver = 2023.7.0.beta2.r31.ge317fd5
+	pkgrel = 1
+	url = https://github.com/NickvisionApps/tagger
+	arch = aarch64
+	arch = armv7h
+	arch = x86_64
+	arch = i686
+	license = GPL3
+	makedepends = blueprint-compiler
+	makedepends = dotnet-sdk>=7
+	makedepends = git
+	depends = dotnet-runtime>=7
+	depends = ffmpeg
+	depends = libadwaita
+	depends = chromaprint
+	provides = tagger
+	conflicts = tagger
+	source = git+https://github.com/NickvisionApps/tagger
+	b2sums = SKIP
+
+pkgname = tagger-git
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..027b4df91703
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,36 @@
+# Maintainer: Mattia Borda <mattiagiovanni.borda@icloud.com>
+
+pkgname=tagger-git
+pkgver=2023.7.0.beta2.r31.ge317fd5
+pkgrel=1
+pkgdesc='Tag your music'
+arch=(aarch64 armv7h x86_64 i686)
+url=https://github.com/NickvisionApps/${pkgname%-git}
+license=(GPL3)
+depends=('dotnet-runtime>=7' ffmpeg libadwaita chromaprint)
+makedepends=(blueprint-compiler 'dotnet-sdk>=7' git)
+provides=(${pkgname%-git})
+conflicts=(${pkgname%-git})
+source=(git+$url)
+b2sums=(SKIP)
+
+pkgver() {
+	cd ${pkgname%-git}
+	git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+prepare() {
+	cd ${pkgname%-git}
+	dotnet tool restore
+}
+
+build() {
+	cd ${pkgname%-git}
+	dotnet cake --target=Publish --prefix=/usr --ui=gnome
+}
+
+package() {
+	cd ${pkgname%-git}
+	dotnet cake --target=Install --destdir="$pkgdir"
+	ln -sv org.nickvision.tagger "$pkgdir"/usr/bin/tagger
+}