initial commit

3 files changed, 80 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..fea463dd2a7f
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,24 @@
+pkgbase = themix-export-spotify-git
+	pkgdesc = Export plugin for Themix GUI designer to apply color palettes to Spotify desktop player
+	pkgver = 1.2.r3.g931685f
+	pkgrel = 1
+	url = https://github.com/themix-project/oomoxify
+	arch = x86_64
+	arch = i686
+	license = GPL3
+	makedepends = git
+	makedepends = python
+	depends = grep
+	depends = bc
+	depends = zip
+	depends = polkit
+	optdepends = themix-gui: GUI
+	optdepends = gksu: for applying Spotify theme from GUI without polkit
+	provides = themix-export-spotify
+	conflicts = themix-export-spotify
+	options = !strip
+	source = oomoxify::git+https://github.com/themix-project/oomoxify.git#branch=master
+	md5sums = SKIP
+
+pkgname = themix-export-spotify-git
+
diff --git a/.gitignore b/.gitignore
new file mode 100644
index 000000000000..6fae5edaaa1d
--- /dev/null
+++ b/.gitignore
@@ -0,0 +1,5 @@
+pkg/
+src/
+
+oomoxify/
+themix-export-spotify-git-*.pkg.*
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..c66a2b6ddc67
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,51 @@
+# Maintainer: Yauhen Kirylau <actionless DOT loveless PLUS aur AT gmail MF com>
+# Upstream URL: https://github.com/themix-project/oomoxify
+
+_pkgname=themix-export-spotify
+_reponame=oomoxify
+pkgname="${_pkgname}-git"
+pkgver=1.2.r3.g931685f
+pkgrel=1
+pkgdesc="Export plugin for Themix GUI designer to apply color palettes to Spotify desktop player"
+arch=('x86_64' 'i686')
+url="https://github.com/themix-project/${_reponame}"
+license=('GPL3')
+source=(
+	"${_reponame}::git+https://github.com/themix-project/${_reponame}.git#branch=master"
+)
+md5sums=('SKIP')
+depends=(
+	'grep'
+	'bc'
+	'zip'
+	'polkit'
+)
+makedepends=(
+	'git'
+	'python'
+)
+optdepends=(
+	'themix-gui: GUI'
+	'gksu: for applying Spotify theme from GUI without polkit'
+)
+options=(
+	'!strip'
+)
+provides=($_pkgname)
+conflicts=($_pkgname)
+
+pkgver() {
+	cd "${srcdir}/${_reponame}"
+	git describe --long | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+package() {
+	_oomox_dir=/opt/oomox
+	_plugin_name=oomoxify
+
+	cd "${srcdir}/${_reponame}"
+	make -f Makefile_oomox_plugin DESTDIR="${pkgdir}" APPDIR="${_oomox_dir}" PREFIX="/usr" install
+	python -O -m compileall "${pkgdir}${_oomox_dir}/plugins/${_plugin_name}" -d "${_oomox_dir}/plugins/${_plugin_name}"
+}
+
+# vim: ft=PKGBUILD