init

2 files changed, 58 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..902c519656eb
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,17 @@
+pkgbase = trachet-git
+	pkgdesc = Tell you what is happening on your terminal
+	pkgver = r313.cd2be17
+	pkgrel = 1
+	url = https://github.com/saitoha/trachet
+	arch = any
+	license = GPL
+	makedepends = git
+	makedepends = python2-setuptools
+	depends = python2
+	source = git+https://github.com/saitoha/trachet
+	source = git+https://github.com/saitoha/tff
+	md5sums = SKIP
+	md5sums = SKIP
+
+pkgname = trachet-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..79c3cc999d65
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,41 @@
+# Maintainer: Robin Broda <robin at broda dot me>
+
+_pkgname=trachet
+pkgname=${_pkgname}-git
+pkgver=r313.cd2be17
+pkgrel=1
+pkgdesc='Tell you what is happening on your terminal'
+arch=('any')
+url="https://github.com/saitoha/${_pkgname}"
+license=('GPL')
+depends=('python2')
+makedepends=('git' 'python2-setuptools')
+source=("git+${url}"
+        'git+https://github.com/saitoha/tff')
+md5sums=('SKIP' 'SKIP')
+
+pkgver() {
+	cd "${_pkgname}"
+	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+prepare() {
+	cd "${_pkgname}"
+
+	git submodule init
+	git config submodule.trachet/tff.url ${srcdir}/tff
+	git submodule update
+}
+
+build() {
+	cd "${_pkgname}"
+
+	python2 setup.py build
+}
+
+package() {
+	cd "${_pkgname}"
+
+	python2 setup.py install --root="${pkgdir}" --optimize=1 --skip-build
+	echo -n > "${pkgdir}"/usr/lib/python2.7/site-packages/trachet-*-py2.7.egg-info/requires.txt
+}