initial commit

2 files changed, 57 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..000d77cf75ef
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,17 @@
+pkgbase = tree-sitter-java-git
+	pkgdesc = Java grammar for tree-sitter
+	pkgver = 0.19.1.r25.g2efe37f
+	pkgrel = 1
+	url = https://github.com/tree-sitter/tree-sitter-java
+	arch = x86_64
+	groups = tree-sitter-grammars
+	license = MIT
+	makedepends = git
+	makedepends = tree-sitter
+	makedepends = npm
+	provides = tree-sitter-java
+	conflicts = tree-sitter-java
+	source = tree-sitter-java-git::git+https://github.com/tree-sitter/tree-sitter-java
+	sha256sums = SKIP
+
+pkgname = tree-sitter-java-git
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..597e9563e82e
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,40 @@
+# Maintainer: Luis Martinez <luis dot martinez at tuta dot io>
+
+pkgname=tree-sitter-java-git
+pkgver=0.19.1.r25.g2efe37f
+pkgrel=1
+pkgdesc="Java grammar for tree-sitter"
+arch=('x86_64')
+url="https://github.com/tree-sitter/tree-sitter-java"
+license=('MIT')
+groups=('tree-sitter-grammars')
+makedepends=('git' 'tree-sitter' 'npm')
+provides=("${pkgname%-git}")
+conflicts=("${pkgname%-git}")
+source=("$pkgname::git+$url")
+sha256sums=('SKIP')
+
+pkgver() {
+	cd "$pkgname"
+	git describe --long --tags | sed 's/^v//;s/-/.r/;s/-/./'
+}
+
+prepare() {
+	cd "$pkgname"
+	tree-sitter generate
+}
+
+build() {
+	cd "$pkgname/src/"
+	cc $CFLAGS -std=c99 -c parser.c
+	cc $LDFLAGS -shared parser.o -o "$srcdir/parser.so"
+}
+
+package() {
+	install -Dvm 644 parser.so "$pkgdir/usr/lib/libtree-sitter-java.so"
+	install -d "$pkgdir/usr/share/nvim/runtime/parser/"
+	ln -s "/usr/lib/libtree-sitter-java.so" "$pkgdir/usr/share/nvim/runtime/parser/java.so"
+	cd "$pkgname"
+	install -Dvm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
+	install -Dvm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname/"
+}