initial commit

2 files changed, 54 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..e1bfae7a097c
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,17 @@
+pkgbase = tree-sitter-lua-git
+	pkgdesc = Lua grammar for tree-sitter
+	pkgver = 1.6.0.r10.gb6d4e9e
+	pkgrel = 1
+	url = https://github.com/nvim-treesitter/tree-sitter-lua
+	arch = x86_64
+	groups = tree-sitter-grammars
+	license = MIT
+	makedepends = git
+	makedepends = tree-sitter
+	depends = gcc-libs
+	provides = tree-sitter-lua
+	conflicts = tree-sitter-lua
+	source = tree-sitter-lua-git::git+https://github.com/nvim-treesitter/tree-sitter-lua
+	sha256sums = SKIP
+
+pkgname = tree-sitter-lua-git
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..869ece4ae4f0
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,37 @@
+# Maintainer: Luis Martinez <luis dot martinez at tuta dot io>
+
+pkgname=tree-sitter-lua-git
+pkgver=1.6.0.r10.gb6d4e9e
+pkgrel=1
+pkgdesc="Lua grammar for tree-sitter"
+arch=('x86_64')
+url="https://github.com/nvim-treesitter/tree-sitter-lua"
+license=('MIT')
+groups=('tree-sitter-grammars')
+depends=('gcc-libs')
+makedepends=('git' 'tree-sitter')
+provides=("${pkgname%-git}")
+conflicts=("${pkgname%-git}")
+source=("$pkgname::git+$url")
+sha256sums=('SKIP')
+
+pkgver() {
+	cd "$pkgname"
+	git describe --long --tags | sed 's/^v//;s/-/.r/;s/-/./'
+}
+
+build() {
+	cd "$pkgname/src/"
+	cc $CFLAGS -std=c99 -c parser.c
+	c++ $CPPFLAGS -c scanner.cc
+	c++ $LDFLAGS -shared parser.o scanner.o -o "$srcdir/parser.so"
+}
+
+package() {
+	install -Dvm 644 parser.so "$pkgdir/usr/lib/libtree-sitter-lua.so"
+	install -d "$pkgdir/usr/share/nvim/runtime/parser/"
+	ln -s "/usr/lib/libtree-sitter-lua.so" "$pkgdir/usr/share/nvim/runtime/parser/lua.so"
+	cd "$pkgname"
+	install -Dvm 644 LICENSE.md -t "$pkgdir/usr/share/licenses/$pkgname/"
+	install -Dvm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname/"
+}