initial commit

2 files changed, 61 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..ad1558dccf65
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,17 @@
+pkgbase = tree-sitter-r-git
+	pkgdesc = R grammar for tree-sitter
+	pkgver = r64.bcf381c
+	pkgrel = 1
+	url = https://github.com/r-lib/tree-sitter-r
+	arch = x86_64
+	groups = tree-sitter-grammars
+	license = MIT
+	makedepends = git
+	makedepends = tree-sitter
+	makedepends = npm
+	provides = tree-sitter-r
+	conflicts = tree-sitter-r
+	source = tree-sitter-r-git::git+https://github.com/r-lib/tree-sitter-r
+	sha256sums = SKIP
+
+pkgname = tree-sitter-r-git
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..449f618c4ec0
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,44 @@
+# Maintainer: Luis Martinez <luis dot martinez at tuta dot io>
+
+pkgname=tree-sitter-r-git
+pkgver=r64.bcf381c
+pkgrel=1
+pkgdesc="R grammar for tree-sitter"
+arch=('x86_64')
+url="https://github.com/r-lib/tree-sitter-r"
+license=('MIT')
+groups=('tree-sitter-grammars')
+makedepends=('git' 'tree-sitter' 'npm')
+provides=("${pkgname%-git}")
+conflicts=("${pkgname%-git}")
+source=("$pkgname::git+$url")
+sha256sums=('SKIP')
+
+pkgver() {
+	cd "$pkgname"
+	( set -o pipefail
+	  git describe --long --tags 2>/dev/null | sed 's/^v//;s/-/.r/;s/-/./' ||
+	  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+	)
+}
+
+prepare() {
+	cd "$pkgname"
+	tree-sitter generate
+}
+
+build() {
+	cd "$pkgname/src/"
+	cc $CFLAGS -std=c99 -c parser.c
+	cc $LDFLAGS -shared parser.o -o "$srcdir/parser.so"
+}
+
+package() {
+	install -Dvm 644 parser.so "$pkgdir/usr/lib/libtree-sitter-r.so"
+	install -d "$pkgdir/usr/share/nvim/runtime/parser/"
+	ln -s "/usr/lib/libtree-sitter-r.so" "$pkgdir/usr/share/nvim/runtime/parser/r.so"
+	cd "$pkgname"
+	install -Dvm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
+	install -Dvm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname/"
+}
+