initial commit

2 files changed, 57 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..69c3995b0895
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,17 @@
+pkgbase = tree-sitter-regex-git
+	pkgdesc = Regex grammar for tree-sitter
+	pkgver = 0.19.0.r0.g3041aa3
+	pkgrel = 1
+	url = https://github.com/tree-sitter/tree-sitter-regex
+	arch = x86_64
+	groups = tree-sitter-grammars
+	license = MIT
+	makedepends = git
+	makedepends = tree-sitter
+	makedepends = npm
+	provides = tree-sitter-regex
+	conflicts = tree-sitter-regex
+	source = tree-sitter-regex-git::git+https://github.com/tree-sitter/tree-sitter-regex
+	sha256sums = SKIP
+
+pkgname = tree-sitter-regex-git
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..1fe3a27922ae
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,40 @@
+# Maintainer: Luis Martinez <luis dot martinez at tuta dot io>
+
+pkgname=tree-sitter-regex-git
+pkgver=0.19.0.r0.g3041aa3
+pkgrel=1
+pkgdesc="Regex grammar for tree-sitter"
+arch=('x86_64')
+url="https://github.com/tree-sitter/tree-sitter-regex"
+license=('MIT')
+groups=('tree-sitter-grammars')
+makedepends=('git' 'tree-sitter' 'npm')
+provides=("${pkgname%-git}")
+conflicts=("${pkgname%-git}")
+source=("$pkgname::git+$url")
+sha256sums=('SKIP')
+
+pkgver() {
+	cd "$pkgname"
+	git describe --long --tags | sed 's/^v//;s/-/.r/;s/-/./'
+}
+
+prepare() {
+	cd "$pkgname"
+	tree-sitter generate
+}
+
+build() {
+	cd "$pkgname/src/"
+	cc $CFLAGS -std=c99 -c parser.c
+	cc $LDFLAGS -shared parser.o -o "$srcdir/parser.so"
+}
+
+package() {
+	install -Dvm 644 parser.so "$pkgdir/usr/lib/libtree-sitter-regex.so"
+	install -d "$pkgdir/usr/share/nvim/runtime/parser/"
+	ln -s "/usr/lib/libtree-sitter-regex.so" "$pkgdir/usr/share/nvim/runtime/parser/regex.so"
+	cd "$pkgname"
+	install -Dvm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
+	install -Dvm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname/"
+}