initial commit

2 files changed, 60 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..1066b9b88ea6
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,17 @@
+pkgbase = tree-sitter-zig-git
+	pkgdesc = Zig grammar for tree-sitter
+	pkgver = r50.41bbc7f
+	pkgrel = 1
+	url = https://github.com/grayjack/tree-sitter-zig
+	arch = x86_64
+	groups = tree-sitter-grammars
+	license = BSD
+	makedepends = git
+	makedepends = tree-sitter
+	makedepends = npm
+	provides = tree-sitter-zig
+	conflicts = tree-sitter-zig
+	source = tree-sitter-zig-git::git+https://github.com/grayjack/tree-sitter-zig
+	sha256sums = SKIP
+
+pkgname = tree-sitter-zig-git
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..fadd14c3bbd6
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,43 @@
+# Maintainer: Luis Martinez <luis dot martinez at tuta dot io>
+
+pkgname=tree-sitter-zig-git
+pkgver=r50.41bbc7f
+pkgrel=1
+pkgdesc="Zig grammar for tree-sitter"
+arch=('x86_64')
+url="https://github.com/grayjack/tree-sitter-zig"
+license=('BSD')
+groups=('tree-sitter-grammars')
+makedepends=('git' 'tree-sitter' 'npm')
+provides=("${pkgname%-git}")
+conflicts=("${pkgname%-git}")
+source=("$pkgname::git+$url")
+sha256sums=('SKIP')
+
+pkgver() {
+	cd "$pkgname"
+	( set -o pipefail
+	  git describe --long --tags 2>/dev/null | sed 's/^v//;s/-/.r/;s/-/./' ||
+	  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+	)
+}
+
+prepare() {
+	cd "$pkgname"
+	tree-sitter generate
+}
+
+build() {
+	cd "$pkgname/src/"
+	cc $CFLAGS -std=c99 -c parser.c
+	cc $LDFLAGS -shared parser.o -o "$srcdir/parser.so"
+}
+
+package() {
+	install -Dvm 644 parser.so "$pkgdir/usr/lib/libtree-sitter-zig.so"
+	install -d "$pkgdir/usr/share/nvim/runtime/parser/"
+	ln -s "/usr/lib/libtree-sitter-zig.so" "$pkgdir/usr/share/nvim/runtime/parser/zig.so"
+	cd "$pkgname"
+	install -Dvm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
+	install -Dvm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname/"
+}