twittuh-git: initial import

3 files changed, 59 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..68ece040e0aa
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,14 @@
+pkgbase = twittuh-git
+	pkgdesc = Small Go program to make RSS/ATOM/JSON feeds from Twitter timelines
+	pkgver = r89.ef45111
+	pkgrel = 1
+	url = https://github.com/derat/twittuh
+	arch = x86_64
+	license = BSD
+	makedepends = go
+	depends = chromium
+	source = twittuh::git+https://github.com/derat/twittuh.git#branch=master
+	sha256sums = SKIP
+
+pkgname = twittuh-git
+
diff --git a/.gitignore b/.gitignore
new file mode 100644
index 000000000000..17f5c6dfca74
--- /dev/null
+++ b/.gitignore
@@ -0,0 +1,4 @@
+pkg/
+src/
+twittuh/
+*.tar.*
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..be979cc5bece
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,41 @@
+# Maintainer: gbr <gbr@protonmail.com>
+_pkgname=twittuh
+pkgname=twittuh-git
+pkgver=r89.ef45111
+pkgrel=1
+pkgdesc='Small Go program to make RSS/ATOM/JSON feeds from Twitter timelines'
+arch=('x86_64')
+url='https://github.com/derat/twittuh'
+license=('BSD')
+depends=('chromium')
+makedepends=('go')
+source=("$_pkgname::git+https://github.com/derat/twittuh.git#branch=master")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "$_pkgname"
+  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+build() {
+    cd "$srcdir/$_pkgname"
+    go build \
+        -o "$_pkgname" \
+        -trimpath \
+        -buildmode=pie \
+        -mod=readonly \
+        -modcacherw \
+        -ldflags "-extldflags \"${LDFLAGS}\"" \
+        .
+}
+
+check() {
+    cd "$srcdir/$_pkgname"
+    go test -v ./...
+}
+
+package() {
+    cd "$srcdir/$_pkgname"
+    install -Dm755 $_pkgname "$pkgdir"/usr/bin/$_pkgname
+    install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$_pkgname/LICENSE"
+}