Initial commit

3 files changed, 69 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..eb974f59731a
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,17 @@
+pkgbase = vapoursynth-plugin-reconstruct-git
+	pkgdesc = Plugin for Vapoursynth: reconstruct (GIT version)
+	pkgver = 0.1.0.0.g36eec61
+	pkgrel = 1
+	url = https://github.com/Irrational-Encoding-Wizardry/vapoursynth-reconstruct.git
+	arch = x86_64
+	license = GPL
+	makedepends = git
+	depends = vapoursynth
+	depends = gcc-libs
+	depends = glibc
+	provides = vapoursynth-plugin-reconstruct
+	conflicts = vapoursynth-plugin-reconstruct
+	source = reconstruct::git+https://github.com/Irrational-Encoding-Wizardry/vapoursynth-reconstruct.git
+	sha256sums = SKIP
+
+pkgname = vapoursynth-plugin-reconstruct-git
diff --git a/.gitignore b/.gitignore
new file mode 100644
index 000000000000..05c6d4d4c97b
--- /dev/null
+++ b/.gitignore
@@ -0,0 +1,4 @@
+*
+!.gitignore
+!.SRCINFO
+!PKGBUILD
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..109a411a3275
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,48 @@
+# Maintainer: Gustavo Alvarez <sl1pkn07@gmail.com>
+
+_plug=reconstruct
+pkgname=vapoursynth-plugin-${_plug}-git
+pkgver=0.1.0.0.g36eec61
+pkgrel=1
+pkgdesc="Plugin for Vapoursynth: ${_plug} (GIT version)"
+arch=('x86_64')
+url='https://github.com/Irrational-Encoding-Wizardry/vapoursynth-reconstruct.git'
+license=('GPL')
+depends=(
+  'vapoursynth'
+  'gcc-libs'
+  'glibc'
+)
+makedepends=('git')
+provides=("vapoursynth-plugin-${_plug}")
+conflicts=("vapoursynth-plugin-${_plug}")
+source=("${_plug}::git+https://github.com/Irrational-Encoding-Wizardry/vapoursynth-reconstruct.git")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "${_plug}"
+  echo "$(git describe --long --tags | tr - . | tr -d v)"
+#   printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+prepare() {
+  cd "${_plug}"
+
+  sed '12a#include <string>' -i recon.cpp
+
+  echo "all:
+	  g++ -c -std=c++17 -I./kernel $(pkg-config --cflags vapoursynth) ${CXXFLAGS} ${CPPFLAGS} -fPIC  -o kernel/cpufeatures.o kernel/cpufeatures.cpp
+	  g++ -c -std=c++17 -I./kernel $(pkg-config --cflags vapoursynth) ${CXXFLAGS} ${CPPFLAGS} -fPIC  -o kernel/cpulevel.o kernel/cpulevel.cpp
+
+	  g++ -c -std=c++17 -I. $(pkg-config --cflags vapoursynth) ${CXXFLAGS} ${CPPFLAGS} -fPIC -o recon.o recon.cpp
+
+	  g++ -std=c++17 -shared -o libvs${_plug}.so kernel/*.o *.o $(pkg-config --libs vapoursynth) ${CXXFLAGS} ${CPPFLAGS} ${LDFLAGS}"> Makefile
+}
+
+build() {
+  make -C "${_plug}"
+}
+
+package() {
+  install -Dm755 "${_plug}/libvs${_plug}.so" "${pkgdir}/usr/lib/vapoursynth/libvs${_plug}.so"
+}