summarylogtreecommitdiffstats
diff options
context:
space:
mode:
authorManuel Reimer2019-01-13 15:34:58 +0100
committerManuel Reimer2019-01-13 15:34:58 +0100
commitb7a66fe8335adcea213ccd6608216e4e4e0621aa (patch)
tree832409e10a2c42b790832d6f149e678b32145299
downloadaur-b7a66fe8335adcea213ccd6608216e4e4e0621aa.tar.gz
Sync from VDR4Arch (https://github.com/VDR4Arch/vdr4arch/commit/dcdbba8b483e5e7f8c4ad38319449d09a7fd9bd9)
-rw-r--r--.SRCINFO32
-rw-r--r--50-softhdcuvid.conf52
-rw-r--r--PKGBUILD52
3 files changed, 136 insertions, 0 deletions
diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 00000000000..e853affd547
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,32 @@
+# Generated by makepkg 5.1.2
+# Sun Jan 13 14:34:58 UTC 2019
+pkgbase = vdr-softhdcuvid
+ pkgdesc = VDR output plugin with CUDA and Opengl
+ pkgver = v1.1.0.r10.g8682ab0
+ pkgrel = 1
+ url = https://github.com/jojo61/vdr-plugin-softhdcuvid
+ arch = x86_64
+ license = AGPL3
+ makedepends = git
+ makedepends = glm
+ makedepends = glu
+ makedepends = vulkan-headers
+ depends = ffmpeg
+ depends = freeglut
+ depends = glew
+ depends = mesa
+ depends = vdr-api=2.4.0
+ depends = xcb-util-wm
+ depends = xorg-server
+ depends = cuda
+ depends = nvidia>=410.48
+ depends = libplacebo>=1.7.0
+ optdepends = vdr-xorg: Recommended way to start X.org server together with VDR
+ backup = etc/vdr/conf.avail/50-softhdcuvid.conf
+ source = vdr-plugin-softhdcuvid::git+https://github.com/jojo61/vdr-plugin-softhdcuvid#commit=8682ab01c440346212d65a91c5c4639a65d6473d
+ source = 50-softhdcuvid.conf
+ sha512sums = SKIP
+ sha512sums = 0b336e5d0c18e5a875389c52d498ce81db0a407c6a93e1e72e0d0faec41d2165b80e91e9787465bb2cb9923ca65e6ce50e4a086f0d26410059899fef2bbe87b0
+
+pkgname = vdr-softhdcuvid
+
diff --git a/50-softhdcuvid.conf b/50-softhdcuvid.conf
new file mode 100644
index 00000000000..1fc659d7dbb
--- /dev/null
+++ b/50-softhdcuvid.conf
@@ -0,0 +1,52 @@
+[softhdcuvid]
+#-a device
+# audio device (fe. alsa: hw:0,0)
+
+#-c channel
+# audio mixer channel name (fe. PCM)
+
+#-d display
+# display of x11 server (fe. :0.0)
+
+#-D
+# start in detached mode
+
+#-f
+# start with fullscreen window (only with window manager)
+
+#-g geometry
+# x11 window geometry wxh+x+y
+
+#-p device
+# audio device for pass-through (hw:0,1)
+
+#-s
+# start in suspended mode
+
+#-v device
+# video driver device (va-api, vdpau, noop)
+
+#-w workaround
+# enable/disable workarounds
+# no-hw-decoder
+# disable hw decoder, use software decoder only
+# no-mpeg-hw-decoder
+# disable hw decoder for mpeg only
+# still-hw-decoder
+# enable hardware decoder for still-pictures
+# still-h264-hw-decoder
+# enable h264 hw decoder for still-pictures
+# alsa-driver-broken
+# disable broken alsa driver message
+# alsa-no-close-open
+# disable close open to fix alsa no sound bug
+# alsa-close-open-delay
+# enable close open delay to fix no sound bug
+# ignore-repeat-pict
+# disable repeat pict message
+
+#-x
+# start x11 server, with -xx try to connect, if this fails
+
+#-X args
+# X11 server arguments (f.e. -nocursor)
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 00000000000..ee6e7a56c03
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,52 @@
+# This PKGBUILD is part of the VDR4Arch project [https://github.com/vdr4arch]
+pkgname=vdr-softhdcuvid
+pkgver=v1.1.0.r10.g8682ab0
+_gitver=8682ab01c440346212d65a91c5c4639a65d6473d
+_vdrapi=2.4.0
+pkgrel=1
+pkgdesc="VDR output plugin with CUDA and Opengl"
+url="https://github.com/jojo61/vdr-plugin-softhdcuvid"
+arch=('x86_64')
+license=('AGPL3')
+depends=('ffmpeg' 'freeglut' 'glew' 'mesa' "vdr-api=${_vdrapi}" 'xcb-util-wm' 'xorg-server' 'cuda' 'nvidia>=410.48' 'libplacebo>=1.7.0')
+optdepends=('vdr-xorg: Recommended way to start X.org server together with VDR')
+makedepends=('git' 'glm' 'glu' 'vulkan-headers')
+_plugname=${pkgname//vdr-/}
+source=("vdr-plugin-${_plugname}::git+https://github.com/jojo61/vdr-plugin-softhdcuvid#commit=$_gitver"
+ "50-$_plugname.conf")
+backup=("etc/vdr/conf.avail/50-$_plugname.conf")
+sha512sums=('SKIP'
+ '0b336e5d0c18e5a875389c52d498ce81db0a407c6a93e1e72e0d0faec41d2165b80e91e9787465bb2cb9923ca65e6ce50e4a086f0d26410059899fef2bbe87b0')
+
+pkgver() {
+ cd "${srcdir}/vdr-plugin-${_plugname}"
+ git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+prepare() {
+ cd "${srcdir}/vdr-plugin-${_plugname}"
+
+ # Disable OSS. Arch Linux doesn't ship OSS
+ sed -i '/OSS /d' Makefile
+
+ # Enable libplacebo
+ sed -i 's/LIBPLACEBO=0/LIBPLACEBO=1/' Makefile
+
+ # Adapt path to cuda headers, in arch they are installed in /opt/cuda/include
+ sed -i 's%/usr/local/cuda/include%/opt/cuda/include%' Makefile
+
+ # Adapt path to cuda libraries, in arch the are installed in /opt/cuda/lib64
+ sed -i 's%-L/usr/local/cuda/targets/x86_64-linux/lib%-L/opt/cuda/lib64%' Makefile
+}
+
+build() {
+ cd "${srcdir}/vdr-plugin-${_plugname}"
+ make
+}
+
+package() {
+ cd "${srcdir}/vdr-plugin-${_plugname}"
+ make DESTDIR="${pkgdir}" install
+
+ install -Dm644 "$srcdir/50-$_plugname.conf" "$pkgdir/etc/vdr/conf.avail/50-$_plugname.conf"
+}