init

2 files changed, 61 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..bbe1c4cf085e
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,18 @@
+pkgbase = vim-coc-tabnine-git
+	pkgdesc = Tabnine integration of coc.nvim
+	pkgver = 1.2.2.r2.g442c829
+	pkgrel = 1
+	url = https://github.com/neoclide/coc-tabnine
+	arch = any
+	license = MIT
+	makedepends = yarn
+	makedepends = npm
+	makedepends = git
+	depends = vim-coc
+	provides = vim-coc-tabnine
+	conflicts = vim-coc-tabnine
+	source = coc-tabnine::git+https://github.com/neoclide/coc-tabnine.git
+	sha256sums = SKIP
+
+pkgname = vim-coc-tabnine-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..fef8fd6f1e1b
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,43 @@
+# Maintainer: Sainnhe Park <sainnhe@gmail.com>
+_variant='vim'
+_extname=coc-tabnine
+_packdir="usr/share/vim/vimfiles/pack/coc/start/${_extname}"
+url='https://github.com/neoclide/coc-tabnine'
+pkgdesc='Tabnine integration of coc.nvim'
+
+pkgname="${_variant}-${_extname}-git"
+provides=("${_variant}-${_extname}")
+conflicts=("${_variant}-${_extname}")
+arch=('any')
+depends=("${_variant}-coc")
+makedepends=('yarn' 'npm' 'git')
+license=('MIT')
+source=("${_extname}::git+${url}.git")
+pkgver=1.2.2.r2.g442c829
+pkgrel=1
+sha256sums=('SKIP')
+
+pkgver() {
+    cd "${srcdir}/${_extname}"
+    git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+    cd "${srcdir}/${_extname}"
+    yarn install --frozen-lockfile --preferred-cache-folder "${srcdir}/.cache"
+}
+
+package() {
+    cd "${srcdir}/${_extname}"
+    yarn pack; tar xvf *.tgz; rm *.tgz
+    cd package
+    _dependencies=$(grep -Po '"dependencies":' package.json) || _dependencies=""
+    if [ -n "${_dependencies}" ]; then
+        yarn install --production --no-lockfile --ignore-scripts --prefer-offline --preferred-cache-folder "${srcdir}/.cache"
+    fi
+    find . -type f -exec \
+        install -Dm 644 '{}' "${pkgdir}/${_packdir}/{}" \;
+    rm -rf "${srcdir}/${_extname}/package"
+    find "$pkgdir" -name package.json -print0 | xargs -r -0 sed -i '/_where/d'
+    chown -R root:root "${pkgdir}"
+}