initial commit

2 files changed, 71 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..7cf036ff4810
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,25 @@
+pkgbase = vim-minimap-git
+	pkgdesc = Blazing fast minimap for Vim, powered by code-minimap
+	pkgver = r116.408db1f
+	pkgrel = 1
+	url = https://github.com/wfxr/minimap.vim
+	arch = any
+	groups = vim-plugins
+	license = MIT
+	makedepends = git
+	depends = code-minimap
+	source = vim-minimap-git::git+https://github.com/wfxr/minimap.vim
+	sha256sums = SKIP
+
+pkgname = vim-minimap-git
+	depends = code-minimap
+	depends = vim>=8.2
+	provides = vim-minimap
+	conflicts = vim-minimap
+
+pkgname = neovim-minimap-git
+	depends = code-minimap
+	depends = neovim-git
+	provides = neovim-minimap
+	conflicts = neovim-minimap
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..3ce7bc12b38a
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,46 @@
+# Maintainer: Luis Martinez <luis dot martinez at tuta dot io>
+
+pkgbase=vim-minimap-git
+pkgname=('vim-minimap-git' 'neovim-minimap-git')
+pkgver=r116.408db1f
+pkgrel=1
+pkgdesc="Blazing fast minimap for Vim, powered by code-minimap"
+arch=('any')
+url="https://github.com/wfxr/minimap.vim"
+license=('MIT')
+groups=('vim-plugins')
+depends=('code-minimap')
+makedepends=('git')
+source=("$pkgbase::git+$url")
+sha256sums=('SKIP')
+
+pkgver() {
+	cd "$pkgbase"
+	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+package_vim-minimap-git()  {
+	depends+=('vim>=8.2')
+	provides=("${pkgname%-git}")
+	conflicts=("${pkgname%-git}")
+
+	cd "$pkgbase"
+	find autoload doc plugin \
+	  -type f -exec install -Dvm 644 '{}' "$pkgdir/usr/share/vim/vimfiles/{}" \;
+	install -Dvm 755 bin/minimap_generator.sh -t "$pkgdir/usr/share/vim/vimfiles/bin/"
+	install -Dvm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
+	install -Dvm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname/"
+}
+
+package_neovim-minimap-git()  {
+	depends+=('neovim-git')
+	provides=("${pkgname%-git}")
+	conflicts=("${pkgname%-git}")
+
+	cd "$pkgbase"
+	find autoload doc plugin \
+	  -type f -exec install -Dvm 644 '{}' "$pkgdir/usr/share/nvim/runtime/{}" \;
+	install -Dvm 755 bin/minimap_generator.sh -t "$pkgdir/usr/share/nvim/runtime/bin/"
+	install -Dvm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
+	install -Dvm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname/"
+}