Initial release of git version to AUR

2 files changed, 58 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..1eeac17d29eb
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,17 @@
+pkgbase = vipster-git
+	pkgdesc = Molecule editor based on Qt, specialized on periodic structures, development version
+	pkgver = r806.e00e69b
+	pkgrel = 1
+	url = https://sgsaenger.github.io/vipster
+	arch = x86_64
+	license = GPL3
+	makedepends = qbs
+	makedepends = git
+	depends = qt5-base
+	depends = python
+	conflicts = vipster
+	source = git+https://github.com/sgsaenger/vipster#branch=testing
+	md5sums = SKIP
+
+pkgname = vipster-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..b9e8e7bb31ff
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,41 @@
+# Maintainer: Sebastian Gsänger <sebastian_gsaenger@web.de>
+pkgname=vipster-git
+pkgver=r806.e00e69b
+pkgrel=1
+pkgdesc="Molecule editor based on Qt, specialized on periodic structures, development version"
+arch=('x86_64')
+url="https://sgsaenger.github.io/vipster"
+license=('GPL3')
+groups=()
+depends=('qt5-base' 'python')
+makedepends=('qbs' 'git')
+conflicts=('vipster')
+source=("git+https://github.com/sgsaenger/vipster#branch=testing")
+md5sums=('SKIP')
+
+pkgver() {
+    cd vipster
+    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+build() {
+  cd vipster
+
+  qbs setup-toolchains --settings-dir . `which g++` gcc
+  qbs setup-qt --settings-dir . `which qmake` qt
+  qbs config --settings-dir . profiles.qt.baseProfile gcc
+
+  qbs build --settings-dir . profile:qt qbs.buildVariant:release project.pythonBuild:true --no-install
+}
+
+check() {
+    cd vipster
+
+    qbs run --settings-dir . --products test_libvipster
+}
+
+package() {
+  cd vipster
+
+  qbs install --settings-dir . --install-root $pkgdir/usr
+}