Initial commit

2 files changed, 111 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..5763c7decd2d
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,39 @@
+pkgbase = waybar-hyprland-git
+	pkgdesc = Highly customizable Wayland bar for Sway and Wlroots based compositors, with workspaces support for Hyprland (git version)
+	pkgver = r2001.d10d9b8
+	pkgrel = 1
+	url = https://github.com/Alexays/Waybar/
+	arch = x86_64
+	license = MIT
+	makedepends = cmake
+	makedepends = catch2
+	makedepends = meson
+	makedepends = scdoc
+	makedepends = wayland-protocols
+	depends = gtkmm3
+	depends = libjsoncpp.so
+	depends = libsigc++
+	depends = fmt
+	depends = wayland
+	depends = libdate-tz.so
+	depends = libspdlog.so
+	depends = gtk-layer-shell
+	depends = libupower-glib.so
+	depends = upower
+	depends = libevdev
+	depends = libpulse
+	depends = libnl
+	depends = libappindicator-gtk3
+	depends = libdbusmenu-gtk3
+	depends = libmpdclient
+	depends = libsndio.so
+	depends = libxkbcommon
+	optdepends = otf-font-awesome: Icons in the default configuration
+	provides = waybar
+	conflicts = waybar
+	backup = etc/xdg/waybar/config
+	backup = etc/xdg/waybar/style.css
+	source = waybar-hyprland-git::git+https://github.com/Alexays/Waybar
+	sha1sums = SKIP
+
+pkgname = waybar-hyprland-git
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..8c7b2bac3ad5
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,72 @@
+# Maintainer: Bruno Ancona <bruno at powerball253 dot com>
+
+pkgname=waybar-hyprland-git
+pkgver=r2001.d10d9b8
+pkgrel=1
+pkgdesc='Highly customizable Wayland bar for Sway and Wlroots based compositors, with workspaces support for Hyprland (git version)'
+arch=('x86_64')
+url='https://github.com/Alexays/Waybar/'
+license=('MIT')
+provides=('waybar')
+conflicts=('waybar')
+depends=(
+    'gtkmm3'
+    'libjsoncpp.so'
+    'libsigc++'
+    'fmt'
+    'wayland'
+    'libdate-tz.so'
+    'libspdlog.so'
+    'gtk-layer-shell'
+    'libupower-glib.so'
+    'upower'
+    'libevdev'
+    'libpulse'
+    'libnl'
+    'libappindicator-gtk3'
+    'libdbusmenu-gtk3'
+    'libmpdclient'
+    'libsndio.so'
+    'libxkbcommon'
+)
+makedepends=(
+    'cmake'
+    'catch2'
+    'meson'
+    'scdoc'
+    'wayland-protocols'
+)
+backup=(
+    etc/xdg/waybar/config
+    etc/xdg/waybar/style.css
+)
+optdepends=(
+    'otf-font-awesome: Icons in the default configuration'
+)
+source=("${pkgname}::git+https://github.com/Alexays/Waybar")
+sha1sums=('SKIP')
+
+pkgver() {
+    cd "${srcdir}/${pkgname}"
+    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+build() {
+    cd "${srcdir}/${pkgname}"
+    rm -rf "${srcdir}/build"
+
+    sed -i 's/zext_workspace_handle_v1_activate(workspace_handle_);/const std::string command = "hyprctl dispatch workspace " + name_;\n\tsystem(command.c_str());/g' src/modules/wlr/workspace_manager.cpp # use hyprctl to switch workspaces
+
+    meson --prefix=/usr \
+          --buildtype=plain \
+          --auto-features=enabled \
+          --wrap-mode=nodownload \
+          "${srcdir}/build"
+    meson configure -Dexperimental=true "${srcdir}/build" # enable experimental features
+    ninja -C "${srcdir}/build"
+}
+
+package() {
+    DESTDIR="$pkgdir" ninja -C "${srcdir}/build" install
+    install -Dm644 "${srcdir}/${pkgname}/LICENSE" -t "$pkgdir/usr/share/licenses/$pkgname/"
+}