adding a discord plugin for weechat

2 files changed, 50 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..71eb8ffa3424
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,17 @@
+pkgbase = weechat-discord-git
+	pkgdesc = discord plugin for weechat
+	pkgver = r61.67d74d1
+	pkgrel = 1
+	url = https://github.com/khyperia/weechat-discord
+	arch = i686
+	arch = x86_64
+	license = MIT
+	makedepends = git
+	makedepends = cargo
+	depends = weechat
+	depends = openssl-1.0
+	source = weechat-discord::git+https://github.com/khyperia/weechat-discord.git
+	md5sums = SKIP
+
+pkgname = weechat-discord-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..968ff0cc14c1
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,33 @@
+# Maintainer : nerfingen <nerfingen at yahoo dot de>
+
+_pkgname=weechat-discord
+pkgname=weechat-discord-git
+pkgver=r61.67d74d1
+pkgrel=1
+pkgdesc="discord plugin for weechat"
+arch=('i686' 'x86_64')
+url="https://github.com/khyperia/weechat-discord"
+license=('MIT')
+depends=('weechat' 'openssl-1.0')
+makedepends=('git' 'cargo')
+optdepends=()
+source=("${_pkgname}::git+https://github.com/khyperia/weechat-discord.git")
+md5sums=('SKIP')
+
+pkgver() {
+  cd "${_pkgname}"
+  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+build() {
+  cd "${_pkgname}"
+  make
+}
+
+package() {
+  cd "${_pkgname}"
+
+  install -D "target/release/libweecord.so" \
+  "${pkgdir}/usr/lib/weechat/plugins/libweecord.so"
+  install -Dm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}