Initial upload: weechat-matrix-rs-git r206.fcd3da2-1

2 files changed, 50 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..1a38f1e486da
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,20 @@
+pkgbase = weechat-matrix-rs-git
+	pkgdesc = Rust rewrite of the Python weechat-matrix script
+	pkgver = r206.fcd3da2
+	pkgrel = 1
+	url = https://github.com/poljar/weechat-matrix-rs
+	arch = x86_64
+	license = ISC
+	makedepends = git
+	makedepends = clang
+	makedepends = llvm
+	makedepends = rust
+	depends = openssl
+	depends = weechat
+	provides = weechat-matrix-rs
+	conflicts = weechat-matrix-rs
+	source = git+https://github.com/poljar/weechat-matrix-rs.git
+	sha512sums = SKIP
+
+pkgname = weechat-matrix-rs-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..7ab99695c6cd
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,30 @@
+# Maintainer: Jonas Witschel <diabonas@archlinux.org>
+pkgname=weechat-matrix-rs-git
+pkgver=r206.fcd3da2
+pkgrel=1
+pkgdesc='Rust rewrite of the Python weechat-matrix script'
+arch=('x86_64')
+url='https://github.com/poljar/weechat-matrix-rs'
+license=('ISC')
+depends=('openssl' 'weechat')
+makedepends=('git' 'clang' 'llvm' 'rust')
+provides=("${pkgname%-git}")
+conflicts=("${pkgname%-git}")
+source=("git+$url.git")
+sha512sums=('SKIP')
+
+pkgver() {
+	cd "${pkgname%-git}"
+	printf 'r%s.%s' "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+build() {
+	cd "${pkgname%-git}"
+	RUSTC_BOOTSTRAP=1 cargo build --release --locked # enable nightly async_closure feature
+}
+
+package() {
+	cd "${pkgname%-git}"
+	install -Dm755 target/release/libmatrix.so "$pkgdir/usr/lib/weechat/plugins/matrix.so"
+	install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
+}