Initial commit

wimboot is a memory kernel loader, similar to memdisk. Unlike memdisk,
wimboot is designed specifially to work with wim images (such as
boot.wim and install.wim).

3 files changed, 65 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..5ce60509e20c
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,18 @@
+pkgbase = wimboot-git
+	pkgdesc = iPXE kernel to boot wim images from network for both UEFI and BIOS system
+	pkgver = v2.5.2.r0.901fe95
+	pkgrel = 1
+	url = https://git.ipxe.org/wimboot.git
+	install = wimboot-git.install
+	arch = any
+	license = GPL
+	makedepends = git
+	makedepends = pesign
+	makedepends = lcab
+	optdepends = ipxe-git: iPXE network boot program
+	optdepends = ipxe-netboot: Alternative iPXE network boot program, with Archlinux network install support
+	source = wimboot::git+https://git.ipxe.org/wimboot.git
+	md5sums = SKIP
+
+pkgname = wimboot-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..cb5961152e27
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,34 @@
+# Maintainer: Alif <alive4ever at live.com>
+pkgname=wimboot-git
+pkgver=v2.5.2.r0.901fe95
+pkgrel=1
+pkgdesc="iPXE kernel to boot wim images from network for both UEFI and BIOS system"
+arch=(any)
+url="https://git.ipxe.org/wimboot.git"
+license=('GPL')
+makedepends=('git' 'pesign' 'lcab')
+optdepends=("ipxe-git: iPXE network boot program"
+	"ipxe-netboot: Alternative iPXE network boot program, with Archlinux network install support")
+install=$pkgname.install
+source=('wimboot::git+https://git.ipxe.org/wimboot.git')
+md5sums=('SKIP')
+
+pkgver() {
+	cd "$srcdir/${pkgname%-git}"
+	printf "%s" "$(git describe --long --tags | sed 's/\([^-]*-\)g/r\1/;s/-/./g')"
+}
+
+build() {
+	cd "$srcdir/${pkgname%-git}/src"
+	make
+}	
+
+package() {
+	cd "$srcdir/${pkgname%-git}"
+	install -Dm644 README.txt $pkgdir/usr/share/wimboot/README.txt
+	install -Dm644 LICENSE.txt $pkgdir/usr/share/licenses/wimboot/LICENSE.txt
+	cd "$srcdir/${pkgname%-git}/src"
+	for a in wimboot wimboot.x86_64 wimboot.x86_64.efi wimboot.i386 wimboot.i386.efi wimboot.cab ; do
+	install -Dm755 $a $pkgdir/usr/share/wimboot/$a
+	done
+}
diff --git a/wimboot-git.install b/wimboot-git.install
new file mode 100644
index 000000000000..be7b379333ec
--- /dev/null
+++ b/wimboot-git.install
@@ -0,0 +1,13 @@
+post_install() {
+	cat << EOF
+wimboot needs to be loaded as kernel via iPXE
+network boot program. iPXE will download and map
+additional boot.wim dependencies (bootmgr,
+bootmgr.efi, boot/bcd, and boot/boot.sdi) on
+memory.
+
+For more information, visit
+http://ipxe.org/wimboot
+
+EOF
+}