Initial import

2 files changed, 68 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..5d7c60fed9cc
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,22 @@
+pkgbase = xdg-desktop-portal-liri-git
+	pkgdesc = A Liri backend for xdg-desktop-portal
+	pkgver = 20180425.268.f1c033c
+	pkgrel = 1
+	url = https://liri.io
+	arch = i686
+	arch = x86_64
+	arch = armv6h
+	arch = armv7h
+	groups = liri-git
+	license = GPL3
+	makedepends = git
+	makedepends = liri-qbs-shared-git
+	depends = libliri-git
+	provides = xdg-desktop-portal-liri
+	conflicts = xdg-desktop-portal-liri
+	replaces = xdg-desktop-portal-liri
+	source = xdg-desktop-portal-liri::git://github.com/lirios/xdg-desktop-portal-liri.git#branch=develop
+	md5sums = SKIP
+
+pkgname = xdg-desktop-portal-liri-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..ad65ce35d966
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,46 @@
+# Maintainer: Pier Luigi Fiorini <pierluigi.fiorini@gmail.com>
+
+pkgname=xdg-desktop-portal-liri-git
+pkgver=20180425.268.f1c033c
+pkgrel=1
+pkgdesc="A Liri backend for xdg-desktop-portal"
+arch=('i686' 'x86_64' 'armv6h' 'armv7h')
+url="https://liri.io"
+license=('GPL3')
+depends=('libliri-git')
+makedepends=('git' 'liri-qbs-shared-git')
+conflicts=('xdg-desktop-portal-liri')
+replaces=('xdg-desktop-portal-liri')
+provides=('xdg-desktop-portal-liri')
+groups=('liri-git')
+
+_gitroot="git://github.com/lirios/xdg-desktop-portal-liri.git"
+_gitbranch=develop
+_gitname=xdg-desktop-portal-liri
+source=(${_gitname}::${_gitroot}#branch=${_gitbranch})
+md5sums=('SKIP')
+
+pkgver() {
+	cd ${srcdir}/${_gitname}
+	echo "$(git log -1 --format="%cd" --date=short | tr -d '-').$(git rev-list --count HEAD).$(git log -1 --format="%h")"
+}
+
+prepare() {
+	cd ${srcdir}/${_gitname}
+	git submodule update --init
+}
+
+build() {
+	cd ${srcdir}/${_gitname}
+	qbs setup-toolchains --type gcc /usr/bin/g++ gcc
+	qbs setup-qt /usr/bin/qmake-qt5 qt5
+	qbs config profiles.qt5.baseProfile gcc
+	qbs build --no-install -d build profile:qt5 \
+		modules.lirideployment.prefix:/usr \
+		modules.lirideployment.qmlDir:lib/qt/qml
+}
+
+package() {
+	cd ${srcdir}/${_gitname}
+	qbs install -d build --no-build -v --install-root $pkgdir profile:qt5
+}