0.3.0.r2.gfcd3764cce

2 files changed, 56 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..52ea7e178d09
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,21 @@
+pkgbase = xemu-git
+	pkgdesc = Original Xbox emulator (fork of XQEMU)
+	pkgver = 0.3.0.r2.gfcd3764cce
+	pkgrel = 1
+	url = https://xemu.app/
+	arch = x86_64
+	license = GPL2
+	makedepends = git
+	makedepends = python
+	depends = sdl2
+	depends = libepoxy
+	depends = pixman
+	depends = gtk3
+	depends = glu
+	provides = xemu
+	conflicts = xemu
+	source = xemu::git+https://github.com/mborgerson/xemu.git
+	md5sums = SKIP
+
+pkgname = xemu-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..2541f538b7bd
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,35 @@
+# Maintainer: Alexandre Bouvier <contact@amb.tf>
+# shellcheck shell=bash disable=SC2034,SC2164
+_pkgname=xemu
+pkgname=$_pkgname-git
+pkgver=0.3.0.r2.gfcd3764cce
+pkgrel=1
+pkgdesc="Original Xbox emulator (fork of XQEMU)"
+arch=('x86_64')
+url="https://xemu.app/"
+license=('GPL2')
+depends=('sdl2' 'libepoxy' 'pixman' 'gtk3' 'glu')
+makedepends=('git' 'python')
+provides=("$_pkgname")
+conflicts=("$_pkgname")
+source=("$_pkgname::git+https://github.com/mborgerson/xemu.git")
+md5sums=('SKIP')
+
+pkgver() {
+	cd $_pkgname
+	git describe --long | sed 's/^xemu-v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+	cd $_pkgname
+	./build.sh
+}
+
+package() {
+	cd $_pkgname
+	# shellcheck disable=SC2154
+	install -Dm755 i386-softmmu/qemu-system-i386 "$pkgdir"/usr/bin/$_pkgname
+	install -Dm644 -t "$pkgdir"/usr/share/$_pkgname/data data/*
+	install -Dm644 ui/xemu.desktop "$pkgdir"/usr/share/applications/$_pkgname.desktop
+	install -Dm644 ui/icons/xemu.svg "$pkgdir"/usr/share/icons/hicolor/scalable/apps/$_pkgname.svg
+}