Initial package creation

3 files changed, 71 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..3e583411f246
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,19 @@
+pkgbase = xmrig-amd-git
+	pkgdesc = Monero cryptocurrency GPU miner (OpenCL for AMD)
+	pkgver = r20.acd215f
+	pkgrel = 1
+	url = https://github.com/xmrig/xmrig-amd
+	changelog = CHANGELOG.md
+	arch = x86_64
+	license = GPL
+	makedepends = git
+	makedepends = cmake
+	makedepends = opencl-headers
+	depends = libuv
+	depends = ocl-icd
+	optdepends = monero: wallet
+	source = git+https://github.com/xmrig/xmrig-amd.git
+	sha256sums = SKIP
+
+pkgname = xmrig-amd-git
+
diff --git a/CHANGELOG.md b/CHANGELOG.md
new file mode 100644
index 000000000000..c085417164d4
--- /dev/null
+++ b/CHANGELOG.md
@@ -0,0 +1,9 @@
+# v2.4.3-beta2
+ - Fixed, auto config wasn't write opencl-platform to config.json.
+ - Added command line option `--print-platforms`.
+ - Fixed 32 bit build.
+ - [#2](https://github.com/xmrig/xmrig-amd/issues/2) Fixed Linux build.
+ - [#3](https://github.com/xmrig/xmrig-amd/issues/3) Fixed macOS build.
+
+# v2.4.3-beta1
+ - First public release.
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..449f3faf7124
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,43 @@
+# Maintainer: Doug Johnson <dougvj@dougvj.net>
+
+pkgname='xmrig-amd-git'
+pkgver=r20.acd215f
+pkgrel=1
+pkgdesc='Monero cryptocurrency GPU miner (OpenCL for AMD)'
+arch=('x86_64')
+url='https://github.com/xmrig/xmrig-amd'
+depends=('libuv' 'ocl-icd')
+optdepends=('monero: wallet')
+makedepends=('git' 'cmake' 'opencl-headers')
+license=('GPL')
+changelog=CHANGELOG.md
+source=("git+https://github.com/xmrig/xmrig-amd.git");
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "$srcdir/xmrig-amd"
+  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+prepare() {
+  cd "$srcdir/xmrig-amd"
+
+  # create build dir
+  [ -d build ] || mkdir build
+
+  # reset default donate level
+  sed -i -e 's/constexpr const int kDonateLevel = 5;/constexpr const int kDonateLevel = 0;/g' src/donate.h
+}
+
+build() {
+  cd "$srcdir/xmrig-amd/build"
+  cmake -DWITH_HTTPD=OFF -DCMAKE_C_COMPILER=gcc-6 -DCMAKE_CXX_COMPILER=g++-6 ..
+  make
+}
+
+package() {
+  install -Dm775 "$srcdir/xmrig-amd/build/xmrig-amd" "$pkgdir/usr/bin/xmrig-amd-git"
+  install -Dm644 "$srcdir/xmrig-amd/src/config.json" "$pkgdir/usr/share/doc/xmrig-amd-git/config.json.example"
+  install -Dm644 "${srcdir}/xmrig-amd/README.md" "${pkgdir}/usr/share/doc/xmrig-amd-git/README.md"
+  install -Dm644 "${srcdir}/xmrig-amd/CHANGELOG.md" "${pkgdir}/usr/share/doc/xmrig-amd-git/CHANGELOG.md"
+}