First commit.

2 files changed, 89 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..f2930d1ce3fb
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,17 @@
+pkgbase = yaics
+	pkgdesc = A simple GNU social client developed in Qt
+	pkgver = 0.5.r29.g1358c1a
+	pkgrel = 1
+	url = https://gitlab.com/stigatle/yaics/
+	arch = i686
+	arch = x86_64
+	license = GPL
+	depends = qt5-base
+	depends = aspell
+	depends = hicolor-icon-theme
+	conflicts = yaics-git
+	source = yaics::git+https://gitlab.com/stigatle/yaics.git
+	sha256sums = SKIP
+
+pkgname = yaics
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..88b1b439db7b
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,72 @@
+# Maintainer: Icaro Perseo <icaroperseo[at]protonmail[dot]com>
+
+pkgname=yaics
+pkgver=0.5.r29.g1358c1a
+pkgrel=1
+pkgdesc="A simple GNU social client developed in Qt"
+arch=('i686' 'x86_64')
+conflicts=('yaics-git')
+url="https://gitlab.com/stigatle/yaics/"
+license=('GPL')
+depends=('qt5-base' 'aspell' 'hicolor-icon-theme')
+source=("${pkgname}::git+https://gitlab.com/stigatle/yaics.git")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  ( set -o pipefail
+    git describe --long 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
+    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+  )
+}
+
+build() {
+  cd $pkgname
+  qmake yaics.pro
+  make
+}
+
+package() {
+  cd $pkgname
+
+  # Bin file
+  install -Dm755 yaics \
+    "$pkgdir/usr/bin/yaics"
+
+  # Desktop file
+  install -Dm644 yaics.desktop \
+    "$pkgdir/usr/share/applications/yaics.desktop"
+
+  # XML file
+  install -Dm644 yaics.appdata.xml \
+    "$pkgdir/usr/share/appdata/yaics.appdata.xml"
+
+  # Icons
+  install -Dm644 icons/16x16/yaics.png \
+    "$pkgdir/usr/share/icons/hicolor/16x16/apps/yaics.png"
+  install -Dm644 icons/32x32/yaics.png \
+    "$pkgdir/usr/share/icons/hicolor/32x32/apps/yaics.png"
+  install -Dm644 icons/48x48/yaics.png \
+    "$pkgdir/usr/share/icons/hicolor/48x48/apps/yaics.png"
+  install -Dm644 icons/64x64/yaics.png \
+    "$pkgdir/usr/share/icons/hicolor/64x64/apps/yaics.png"
+  install -Dm644 icons/80x80/yaics.png \
+    "$pkgdir/usr/share/icons/hicolor/80x80/apps/yaics.png"
+  install -Dm644 icons/yaics.xpm \
+    "$pkgdir/usr/share/pixmaps/yaics.xpm"
+
+  # Translations
+  install -d "$pkgdir/usr/share/yaics/translations"
+  install -Dm644 translations/* \
+    "$pkgdir/usr/share/yaics/translations"
+
+  # Man
+  install -Dm644 docs/yaics.1 \
+    "$pkgdir/usr/share/man/man1/yaics.1"
+
+  # License
+  install -Dm644 COPYING \
+    "${pkgdir}/usr/share/licenses/yaics/LICENSE"
+}
+
+# vim:set ts=2 sw=2 cc=80 et: