newpkg: yajl-git 2.1.0.r5.g5e3a785-1

2 files changed, 67 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..9e939c90e9bd
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,20 @@
+pkgbase = yajl-git
+	pkgdesc = A fast streaming JSON parsing library in C
+	pkgver = 2.1.0.r5.g5e3a785
+	pkgrel = 1
+	url = https://lloyd.github.io/yajl/
+	arch = i686
+	arch = x86_64
+	license = ISC
+	makedepends = git
+	makedepends = cmake
+	depends = glibc
+	provides = yajl
+	provides = libyajl.so
+	conflicts = yajl
+	options = staticlibs
+	source = git+https://github.com/lloyd/yajl.git
+	sha256sums = SKIP
+
+pkgname = yajl-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..3015e55f78ef
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,47 @@
+# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
+
+pkgname=yajl-git
+pkgver=2.1.0.r5.g5e3a785
+pkgrel=1
+pkgdesc="A fast streaming JSON parsing library in C"
+arch=('i686' 'x86_64')
+url="https://lloyd.github.io/yajl/"
+license=('ISC')
+depends=('glibc')
+makedepends=('git' 'cmake')
+provides=('yajl' 'libyajl.so')
+conflicts=('yajl')
+options=('staticlibs')
+source=("git+https://github.com/lloyd/yajl.git")
+sha256sums=('SKIP')
+
+
+pkgver() {
+  cd "yajl"
+
+  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+  cd "yajl"
+
+  cmake \
+    -B "_build" \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_INSTALL_PREFIX="/usr" \
+    ./
+  make -C "_build"
+}
+
+check() {
+  cd "yajl"
+
+  make -C "_build" test test-api
+}
+
+package() {
+  cd "yajl"
+
+  make -C "_build" DESTDIR="$pkgdir" install
+  install -Dm644 "COPYING" -t "$pkgdir/usr/share/licenses/yajl"
+}