Initial commit

2 files changed, 54 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..923bf45a2ade
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,20 @@
+pkgbase = yrsa-font
+	pkgdesc = Serif font for continuous reading on the web (Latin-only)
+	pkgver = 1.002
+	pkgrel = 1
+	url = https://github.com/rosettatype/yrsa-rasa
+	arch = any
+	groups = yrsa-rasa-fonts
+	license = custom:OFL
+	depends = fontconfig
+	depends = xorg-font-utils
+	provides = ttf-font
+	source = yrsa-font-1.002.zip::https://github.com/rosettatype/yrsa-rasa/releases/download/v1.002/Yrsa-fonts-v1.002.zip
+	sha256sums = 60bfb3b29b050aecea66afdacb7f49b8d78001a3973b0d5faf4d0c438ae806d7
+
+pkgname = otf-yrsa-font
+	conflicts = ttf-yrsa-font
+
+pkgname = ttf-yrsa-font
+	conflicts = otf-yrsa-font
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..38330f396aca
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,34 @@
+# Maintainer: Lennard Hofmann <lennard.hofmann@web.de>
+pkgname=('otf-yrsa-font' 'ttf-yrsa-font')
+pkgbase=yrsa-font
+pkgver=1.002
+pkgrel=1
+pkgdesc='Serif font for continuous reading on the web (Latin-only)'
+arch=(any)
+url="https://github.com/rosettatype/yrsa-rasa"
+license=('custom:OFL')
+groups=('yrsa-rasa-fonts')
+depends=('fontconfig' 'xorg-font-utils') # needed for pacman hooks
+provides=('ttf-font')
+source=("$pkgbase-$pkgver.zip::$url/releases/download/v$pkgver/Yrsa-fonts-v$pkgver.zip")
+sha256sums=('60bfb3b29b050aecea66afdacb7f49b8d78001a3973b0d5faf4d0c438ae806d7')
+
+_package() {
+	cd Yrsa
+	install -Dm644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE.txt"
+
+	# txt file is actually a Markdown file:
+	install -Dm644 README.txt "$pkgdir/usr/share/doc/$pkgname/README.md"
+}
+
+package_otf-yrsa-font() {
+	conflicts=('ttf-yrsa-font')
+	_package
+	install -Dm644 -t "$pkgdir/usr/share/fonts/${pkgbase%-font}" otf/*.otf
+}
+
+package_ttf-yrsa-font() {
+	conflicts=('otf-yrsa-font')
+	_package
+	install -Dm644 -t "$pkgdir/usr/share/fonts/${pkgbase%-font}" ttf/*.ttf
+}