adding zograscope-git into AUR

2 files changed, 68 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..0584b4817320
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,21 @@
+pkgbase = zograscope-git
+	pkgdesc = syntax-aware diff that also provides a number of additional tools (zs-diff, zs-find, zs-gdiff, zs-hi, zs-stats)
+	pkgver = r932.5a0a075
+	pkgrel = 1
+	url = https://github.com/xaizek/zograscope
+	arch = x86_64
+	license = AGPL
+	makedepends = git
+	makedepends = boost
+	makedepends = srcml
+	depends = qt5-base
+	depends = libgit2
+	depends = boost-libs
+	optdepends = srcml: srcML related diff features
+	provides = zograscope
+	conflicts = zograscope
+	source = zograscope::git+https://github.com/xaizek/zograscope.git#commit=5a0a0754478e7ae5bd76509d082821202bb5ddf0
+	md5sums = SKIP
+
+pkgname = zograscope-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..55aa5d3ae9cc
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,47 @@
+# Maintainer: Jiachen YANG <farseerfc@gmail.com>
+_pkgname=zograscope
+_commit=5a0a0754478e7ae5bd76509d082821202bb5ddf0
+pkgname=$_pkgname-git
+pkgver=r932.5a0a075
+pkgrel=1
+pkgdesc="syntax-aware diff that also provides a number of additional tools (zs-diff, zs-find, zs-gdiff, zs-hi, zs-stats)"
+arch=(x86_64)
+url="https://github.com/xaizek/zograscope"
+license=('AGPL')
+depends=('qt5-base' 'libgit2' 'boost-libs')
+makedepends=('git' 'boost' 'srcml')
+optdepends=('srcml: srcML related diff features')
+provides=("${pkgname%-git}")
+conflicts=("${pkgname%-git}")
+source=("zograscope::git+$url.git#commit=$_commit")
+md5sums=('SKIP')
+
+# Please refer to the 'USING VCS SOURCES' section of the PKGBUILD man page for
+# a description of each element in the source array.
+
+pkgver() {
+	cd "$srcdir/${_pkgname}"
+	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+prepare() {
+	cd "$srcdir/${_pkgname}"
+	echo 'QT5_PROG := qmake-qt5' >> config.mk
+	echo 'HAVE_LIBGIT2 := yes'   >> config.mk
+}
+
+build() {
+	cd "$srcdir/${_pkgname}"
+	#make LDFLAGS="$LDFLAGS" release
+	make release
+}
+
+check() {
+	cd "$srcdir/${_pkgname}"
+	make check
+}
+
+package() {
+	cd "$srcdir/${_pkgname}"
+	make DESTDIR="$pkgdir/" install
+}