Initial commit

2 files changed, 61 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..4ce951c4d3c5
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,18 @@
+pkgbase = zsync2-git
+	pkgdesc = A file transfer program that's able to connect to rsync servers
+	pkgver = 2.0.0
+	pkgrel = 1
+	url = https://github.com/AppImage/zsync2
+	arch = x86_64
+	license = custom:Artistic
+	makedepends = cmake
+	makedepends = git
+	makedepends = gnutls
+	makedepends = openssl
+	makedepends = zlib
+	depends = curl
+	source = git+https://github.com/AppImage/zsync2.git
+	b2sums = SKIP
+
+pkgname = zsync2-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..d4161cb6b35a
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,43 @@
+# Maintainer: Jonathon Fernyhough <jonathon+m2x+dev>
+
+pkgname=zsync2-git
+pkgver=2.0.0
+pkgrel=1
+pkgdesc="A file transfer program that's able to connect to rsync servers"
+arch=("x86_64")
+url="https://github.com/AppImage/zsync2"
+license=("custom:Artistic")
+depends=(curl)
+makedepends=(cmake git gnutls openssl zlib)
+source=(git+$url.git)
+b2sums=('SKIP')
+
+pkgver() {
+  cd ${pkgname/-git/}
+  ( set -o pipefail
+    git describe --long 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
+    printf "2.0.0r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+  )
+}
+
+prepare() {
+  cd ${pkgname/-git/}
+  git submodule update --init
+}
+
+build() {
+  cd ${pkgname/-git/}
+
+  mkdir -p build && cd build
+  cmake .. -DUSE_SYSTEM_CURL=1 -DBUILD_CPR_TESTS=0 -DCMAKE_INSTALL_PREFIX=/usr -DCMAKE_INSTALL_LIBDIR=lib -DCMAKE_BUILD_TYPE=None
+  make
+}
+
+package() {
+  cd ${pkgname/-git/}/build
+
+  make DESTDIR="$pkgdir" install
+  install -d "$pkgdir/usr/share/licenses/$pkgname"
+
+  install -Dm644 ../COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
+}