Add OpenGM with support for Python 3

2 files changed, 77 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..ec9bfb9c7bb5
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,22 @@
+pkgbase = opengm-git
+	pkgdesc = A C++ Library for Discrete Graphical Models
+	pkgver = r2125.31e01c6
+	pkgrel = 1
+	url = https://github.com/opengm/opengm
+	arch = i686
+	arch = x86_64
+	license = MIT
+	makedepends = git
+	makedepends = cmake
+	makedepends = boost
+	makedepends = python-numpy
+	depends = boost-libs
+	optdepends = python-numpy: Python support
+	optdepends = python-h5py: Python support
+	provides = opengm
+	conflicts = opengm
+	source = git+https://github.com/bluescarni/opengm.git#branch=python3
+	md5sums = SKIP
+
+pkgname = opengm-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..7fc2c35f5bc9
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,55 @@
+# Maintainer: Oliver Mader <b52@reaktor42.de>
+
+pkgname='opengm-git'
+pkgver=r2125.31e01c6
+pkgrel=1
+pkgdesc="A C++ Library for Discrete Graphical Models"
+arch=('i686' 'x86_64')
+url="https://github.com/opengm/opengm"
+license=('MIT')
+depends=('boost-libs')
+makedepends=('git' 'cmake' 'boost' 'python-numpy')
+optdepends=('python-numpy: Python support' 'python-h5py: Python support')
+provides=("${pkgname%-git}")
+conflicts=("${pkgname%-git}")
+source=('git+https://github.com/bluescarni/opengm.git#branch=python3')
+md5sums=('SKIP')
+
+pkgver() {
+	cd "$srcdir/${pkgname%-git}"
+	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+prepare() {
+	cd "$srcdir/${pkgname%-git}"
+
+    sed -i 's/find_package(Boost COMPONENTS python REQUIRED)/find_package(Boost COMPONENTS python3 REQUIRED)/' src/interfaces/python/opengm/CMakeLists.txt
+    sed -i 's/Boost_PYTHON_LIBRARIES/Boost_PYTHON3_LIBRARIES/g' src/interfaces/python/opengm/*/CMakeLists.txt
+}
+
+build() {
+	cd "$srcdir/${pkgname%-git}"
+
+    mkdir -p build/ && cd build/
+
+    cmake \
+        -DCMAKE_INSTALL_PREFIX=/usr \
+        -DBUILD_TUTORIALS=OFF \
+        -DBUILD_EXAMPLES=OFF \
+        -DBUILD_TESTING=OFF \
+        -DBUILD_PYTHON_WRAPPER=ON \
+        -DWITH_BOOST=ON \
+        -DWITH_HDF5=ON \
+        -DWITH_OPENMP=ON \
+        ..
+
+    make
+}
+
+package() {
+	cd "$srcdir/${pkgname%-git}/build"
+
+    make DESTDIR="$pkgdir/" install
+
+    rm -rf "$pkgdir/"{hdf5,inference,opengmcore}
+}