Initial upload: hyprsome-git r17.e3dfeb9-1

2 files changed, 61 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..b4c27d7fd68c
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,15 @@
+pkgbase = hyprsome-git
+	pkgver = r17.e3dfeb9
+	pkgrel = 1
+	url = https://github.com/sopa0/hyprsome
+	arch = x86_64
+	license = GPL3
+	makedepends = cargo
+	makedepends = git
+	depends = hyprland
+	provides = hyprsome=r17.e3dfeb9
+	conflicts = hyprsome
+	source = git+https://github.com/sopa0/hyprsome.git
+	sha256sums = SKIP
+
+pkgname = hyprsome-git
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..db305912efc8
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,46 @@
+# Maintainer: Caleb Maclennan <caleb@alerque.com>
+
+pkgname=hyprsome-git
+_pkgname=${pkgname%-git}
+pkgver=r17.e3dfeb9
+pkgrel=1
+pkgdesc=''
+arch=(x86_64)
+url="https://github.com/sopa0/$_pkgname"
+license=(GPL3)
+depends=(hyprland)
+makedepends=(cargo
+             git)
+provides=("$_pkgname=$pkgver")
+conflicts=("$_pkgname")
+source=("git+$url.git")
+sha256sums=('SKIP')
+
+prepare() {
+	cd "$_pkgname"
+	cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
+}
+
+pkgver() {
+	cd "$_pkgname"
+	printf 'r%s.%s' "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+build() {
+	cd "$_pkgname"
+    export RUSTUP_TOOLCHAIN=stable
+    export CARGO_TARGET_DIR=target
+    cargo build --frozen --release --all-features
+}
+
+check() {
+    cd $_pkgname
+    export RUSTUP_TOOLCHAIN=stable
+    cargo test --frozen --all-features
+}
+
+package() {
+    cd "$_pkgname"
+    install -Dm755 -t "$pkgdir/usr/bin/" "target/release/$_pkgname"
+    install -Dm644 -t "$pkgdir/usr/share/doc/$pkgname/" README.md
+}