upgpkg: python-tpm2-pytss 1.0.0-1: upstream release

This is a complete rewrite of tpm2-pytss from SWIG to CFFI. Sync the
dependencies and the build procedure with the python-tpm2-pytss-git AUR
package, which gradually introduced the necessary changes over time. Also
switch the sources from PyPI to Github in order to be able to verify their
authenticity using the PGP-signed tag.

2 files changed, 34 insertions, 17 deletions

diff --git a/.SRCINFO b/.SRCINFO
index 507ad77824ec..7aa38f5d35cc 100644
--- a/.SRCINFO
+++ b/.SRCINFO
@@ -1,21 +1,29 @@
 pkgbase = python-tpm2-pytss
 	pkgdesc = Python bindings for tpm2-tss
-	pkgver = 0.1.9
+	pkgver = 1.0.0
 	pkgrel = 1
 	url = https://github.com/tpm2-software/tpm2-pytss
 	arch = x86_64
 	license = BSD
-	checkdepends = ibm-sw-tpm2
-	checkdepends = python-cryptography
+	checkdepends = python-pytest
+	checkdepends = swtpm
+	makedepends = git
+	makedepends = python-pkgconfig
 	makedepends = python-setuptools
-	makedepends = swig
+	makedepends = python-setuptools-scm
+	makedepends = python-toml
 	depends = python
+	depends = python-asn1crypto
+	depends = python-cffi
+	depends = python-cryptography
 	depends = tpm2-tss
 	depends = libtss2-esys.so
 	depends = libtss2-fapi.so
+	depends = libtss2-mu.so
 	depends = libtss2-rc.so
 	depends = libtss2-tctildr.so
-	source = https://files.pythonhosted.org/packages/source/t/tpm2-pytss/tpm2-pytss-0.1.9.tar.gz
-	sha256sums = bf95ed874037b459cb160e789ef5982f64c3db4d5efc65affb6cb941ceb40a65
+	source = git+https://github.com/tpm2-software/tpm2-pytss.git?signed#tag=cad39f77780f3fcb45d0cec79d5bf282c853a4e9
+	validpgpkeys = 5B482B8E3E19DA7C978E1D016DE2E9078E1F50C1
+	sha512sums = SKIP
 
 pkgname = python-tpm2-pytss
diff --git a/PKGBUILD b/PKGBUILD
index 35e4a09218f3..513bd51d28e9 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,30 +1,39 @@
 # Maintainer: Jonas Witschel <diabonas@archlinux.org>
 pkgname=python-tpm2-pytss
-_name=${pkgname#python-}
-pkgver=0.1.9
+pkgver=1.0.0
+_tag=cad39f77780f3fcb45d0cec79d5bf282c853a4e9 # git rev-parse "$pkgver"
 pkgrel=1
 pkgdesc='Python bindings for tpm2-tss'
 arch=('x86_64')
 url='https://github.com/tpm2-software/tpm2-pytss'
 license=('BSD')
-depends=('python' 'tpm2-tss' 'libtss2-esys.so' 'libtss2-fapi.so' 'libtss2-rc.so' 'libtss2-tctildr.so')
-makedepends=('python-setuptools' 'swig')
-checkdepends=('ibm-sw-tpm2' 'python-cryptography')
-source=("https://files.pythonhosted.org/packages/source/${_name::1}/$_name/$_name-$pkgver.tar.gz")
-sha256sums=('bf95ed874037b459cb160e789ef5982f64c3db4d5efc65affb6cb941ceb40a65')
+depends=('python' 'python-asn1crypto' 'python-cffi' 'python-cryptography' 'tpm2-tss'
+         'libtss2-esys.so' 'libtss2-fapi.so' 'libtss2-mu.so' 'libtss2-rc.so' 'libtss2-tctildr.so')
+makedepends=('git' 'python-pkgconfig' 'python-setuptools' 'python-setuptools-scm' 'python-toml')
+checkdepends=('python-pytest' 'swtpm')
+source=("git+$url.git?signed#tag=$_tag")
+sha512sums=('SKIP')
+validpgpkeys=('5B482B8E3E19DA7C978E1D016DE2E9078E1F50C1') # William Roberts (Bill Roberts) <william.c.roberts@intel.com>
+
+pkgver() {
+	cd "${pkgname#python-}"
+	git describe | sed 's/\([^-]*-\)g/r\1/;s/-/./g'
+}
 
 build() {
-	cd "$_name-$pkgver"
+	cd "${pkgname#python-}"
 	python setup.py build
 }
 
 check() {
-	cd "$_name-$pkgver"
-	python -B setup.py test
+	cd "${pkgname#python-}"
+	cp build/lib.*/tpm2_pytss/_libtpm2_pytss.abi3.so tpm2_pytss
+	cp build/lib.*/tpm2_pytss/internal/type_mapping.py tpm2_pytss/internal
+	python -B -m pytest
 }
 
 package() {
-	cd "$_name-$pkgver"
+	cd "${pkgname#python-}"
 	python setup.py install --root="$pkgdir" --optimize=1
 	install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
 }