Initial

2 files changed, 54 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..6abaed3c8f14
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,18 @@
+pkgbase = libxinerama-randr-git
+	pkgdesc = Fork of libXinerama using RANDR for it to work in Zaphod mode
+	pkgver = 1.1.4.r3.g55d1524
+	pkgrel = 1
+	url = https://github.com/mkoskar/libxinerama-randr
+	arch = x86_64
+	license = custom
+	makedepends = xorg-util-macros
+	depends = libxext
+	depends = xineramaproto
+	depends = libxrandr>=1.5
+	provides = libxinerama
+	conflicts = libxinerama
+	source = git+https://github.com/mkoskar/libxinerama-randr.git
+	sha256sums = SKIP
+
+pkgname = libxinerama-randr-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..d27e1fa9d9b5
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,36 @@
+# Maintainer: Miroslav Koškár <http://mkoskar.com/>
+
+_basename=libxinerama-randr
+
+pkgname=libxinerama-randr-git
+pkgver=1.1.4.r3.g55d1524
+pkgrel=1
+pkgdesc='Fork of libXinerama using RANDR for it to work in Zaphod mode'
+url='https://github.com/mkoskar/libxinerama-randr'
+license=(custom)
+arch=(x86_64)
+
+depends=(libxext xineramaproto 'libxrandr>=1.5')
+provides=(libxinerama)
+conflicts=(libxinerama)
+makedepends=(xorg-util-macros)
+
+source=("git+https://github.com/mkoskar/$_basename.git")
+sha256sums=(SKIP)
+
+pkgver() {
+    cd "$_basename"
+    git describe --long --tags | sed 's/libXinerama-//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+    cd "$_basename"
+    ./autogen.sh --prefix=/usr
+    make
+}
+
+package() {
+    cd "$_basename"
+    make DESTDIR="$pkgdir" install
+    install -D -m644 -t "$pkgdir/usr/share/licenses/$_basename" COPYING
+}