newpkg: libnetfilter_log-git 1.0.1.r17.gba196a9-1

2 files changed, 54 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..9dfb174261be
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,18 @@
+pkgbase = libnetfilter_log-git
+	pkgdesc = Userspace library providing interface to packets that have been logged by the kernel packet filter
+	pkgver = 1.0.1.r17.gba196a9
+	pkgrel = 1
+	url = https://netfilter.org/projects/libnetfilter_log/index.html
+	arch = i686
+	arch = x86_64
+	license = GPL
+	makedepends = git
+	depends = libnfnetlink
+	depends = libmnl
+	provides = libnetfilter_log
+	conflicts = libnetfilter_log
+	source = git://git.netfilter.org/libnetfilter_log
+	sha256sums = SKIP
+
+pkgname = libnetfilter_log-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..dbe943b37db7
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,36 @@
+# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
+
+pkgname=libnetfilter_log-git
+pkgver=1.0.1.r17.gba196a9
+pkgrel=1
+pkgdesc="Userspace library providing interface to packets that have been logged by the kernel packet filter"
+arch=('i686' 'x86_64')
+url="https://netfilter.org/projects/libnetfilter_log/index.html"
+license=('GPL')
+depends=('libnfnetlink' 'libmnl')
+makedepends=('git')
+provides=('libnetfilter_log')
+conflicts=('libnetfilter_log')
+source=("git://git.netfilter.org/libnetfilter_log")
+sha256sums=('SKIP')
+
+
+pkgver() {
+  cd "libnetfilter_log"
+
+  git describe --long --tags | sed 's/^libnetfilter_log-//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+  cd "libnetfilter_log"
+
+  ./autogen.sh
+  ./configure --prefix="/usr"
+  make
+}
+
+package() {
+  cd "libnetfilter_log"
+
+  make DESTDIR="$pkgdir" install
+}