Initial upload: ftcli-git 0.1.1.r3.g4fc0b3a-1

2 files changed, 63 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..6fdd21a8cf26
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,23 @@
+pkgbase = ftcli-git
+	pkgdesc = A command line font editor
+	pkgver = 0.1.1.r3.g4fc0b3a
+	pkgrel = 1
+	url = https://github.com/ftCLI/ftCLI
+	arch = any
+	license = MIT
+	makedepends = git
+	makedepends = python-setuptools
+	depends = python
+	depends = python-colorama
+	depends = python-click
+	depends = python-brotli
+	depends = python-fonttools>=4.21.1
+	depends = python-skia-pathops
+	depends = python-zopfli
+	provides = ftcli
+	conflicts = ftcli
+	source = ftcli-git::git+https://github.com/ftCLI/ftCLI.git
+	sha256sums = SKIP
+
+pkgname = ftcli-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..b68c3cf1ba56
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,40 @@
+# Maintainer: Caleb Maclennan <caleb@alerque.com>
+
+_upname=ftCLI
+pkgname=ftcli-git
+pkgver=0.1.1.r3.g4fc0b3a
+pkgrel=1
+pkgdesc='A command line font editor'
+arch=(any)
+url="https://github.com/$_upname/$_upname"
+license=('MIT')
+_py_deps=('colorama'
+          'click'
+          'brotli'
+          'fonttools>=4.21.1'
+          'skia-pathops'
+          'zopfli')
+depends=('python'
+         "${_py_deps[@]/#/python-}")
+makedepends=('git' 'python-setuptools')
+provides=("${pkgname%-git}")
+conflicts=("${pkgname%-git}")
+source=("$pkgname::git+$url.git")
+sha256sums=('SKIP')
+
+pkgver() {
+    cd "$pkgname"
+    git describe --long --tags --abbrev=7 HEAD |
+        sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+    cd "$pkgname"
+    python setup.py build
+}
+
+package() {
+    cd "$pkgname"
+    python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+}
+