First commit. Full build and patch working

2 files changed, 76 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..63c768329224
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,20 @@
+# Generated by mksrcinfo v8
+# Wed Aug  3 18:32:42 UTC 2016
+pkgbase = gnome-shell-theme-arc-clearly-dark-git
+	pkgdesc = Customized GNOME Shell theme featuring cleanliness and no outlines. Based on vanilla Arc Dark theme
+	pkgver = 564.9478b8d.13
+	pkgrel = 1
+	url = https://github.com/icasdri/Arc-Clearly-Dark
+	arch = any
+	license = GPLv3
+	makedepends = git
+	makedepends = python
+	depends = gnome-shell
+	optdepends = gnome-tweak-tool: user interface to theme selection and other GNOME Shell options
+	source = git+https://github.com/icasdri/Arc-Clearly-Dark.git
+	source = git+https://github.com/horst3180/arc-theme.git
+	sha256sums = SKIP
+	sha256sums = SKIP
+
+pkgname = gnome-shell-theme-arc-clearly-dark-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..ed150b32d74c
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,56 @@
+# Maintainer icasdri <icasdri at gmail dot com>
+
+_upstream=arc-theme
+_pkgname=Arc-Clearly-Dark
+pkgname=gnome-shell-theme-arc-clearly-dark-git
+pkgver=564.9478b8d.13
+pkgrel=1
+pkgdesc='Customized GNOME Shell theme featuring cleanliness and no outlines. Based on vanilla Arc Dark theme'
+arch=(any)
+url="https://github.com/icasdri/Arc-Clearly-Dark"
+license=('GPLv3')
+depends=('gnome-shell')
+makedepends=('git' 'python')
+optdepends=('gnome-tweak-tool: user interface to theme selection and other GNOME Shell options')
+source=("git+${url}.git"
+        "git+https://github.com/horst3180/${_upstream}.git")
+sha256sums=('SKIP'
+            'SKIP')
+
+pkgver() {
+    cd "${srcdir}/${_pkgname}"
+    modver=$(git rev-list --count HEAD)
+    cd "${srcdir}/${_upstream}"
+    origver="$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
+    echo "${origver}.${modver}"
+}
+
+build() {
+    cd "${srcdir}/${_upstream}"
+
+    msg2 'Building vanilla Arc Dark theme for GNOME Shell...'
+    ./autogen.sh --prefix=/usr \
+                 --disable-light \
+                 --disable-darker \
+                 --disable-cinnamon \
+                 --disable-gtk2 \
+                 --disable-gtk3 \
+                 --disable-metacity \
+                 --disable-unity \
+                 --disable-xfwm
+
+    cd "${srcdir}"
+    make -C "${srcdir}/${_upstream}" DESTDIR="${srcdir}/${_pkgname}" install
+
+    msg2 'Patching theme for Arc Clearly Dark...'
+    cd "${srcdir}/${_pkgname}"
+    cp 'patch.py' 'usr/share/themes/Arc-Dark'
+    cd 'usr/share/themes/Arc-Dark'
+    python patch.py
+}
+
+package() {
+    cd "${srcdir}/${_pkgname}/usr/share/themes/Arc-Dark"
+    mkdir -p "${pkgdir}/usr/share/themes/Arc-Clearly-Dark"
+    cp -r 'gnome-shell' "${pkgdir}/usr/share/themes/Arc-Clearly-Dark"
+}