v0.101.0

2 files changed, 69 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..4fe77f1c585e
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,18 @@
+pkgbase = devhub-appimage
+	pkgdesc = TweetDeck for GitHub - AppImage version
+	pkgver = 0.101.0
+	pkgrel = 1
+	url = https://github.com/devhubapp/devhub
+	arch = x86_64
+	license = GPL3
+	depends = zlib
+	depends = hicolor-icon-theme
+	provides = devhub
+	conflicts = devhub
+	noextract = devhub-0.101.0.AppImage
+	options = !strip
+	source_x86_64 = devhub-0.101.0.AppImage::https://github.com/devhubapp/devhub/releases/download/v0.101.0/DevHub-0.101.0.AppImage
+	sha256sums_x86_64 = bd09da30167862808d3ded1a740ed2bad267a2a5529da44743c8d29b31b91604
+
+pkgname = devhub-appimage
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..2026826dd515
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,51 @@
+# Maintainer: Vitaliy Volynskiy <i at vitalya.me>
+# Based on https://daveparrish.net/posts/2019-11-16-Better-AppImage-PKGBUILD-template.html
+
+_pkgname=devhub
+
+pkgname="${_pkgname}"-appimage
+pkgver=0.101.0
+pkgrel=1
+pkgdesc="TweetDeck for GitHub - AppImage version"
+arch=('x86_64')
+url="https://github.com/devhubapp/devhub"
+license=('GPL3')
+depends=('zlib' 'hicolor-icon-theme')
+options=(!strip)
+provides=('devhub')
+conflicts=('devhub')
+_appimage="${_pkgname}-${pkgver}.AppImage"
+source_x86_64=("${_appimage}::https://github.com/devhubapp/devhub/releases/download/v${pkgver}/DevHub-${pkgver}.AppImage")
+noextract=("${_appimage}")
+sha256sums_x86_64=('bd09da30167862808d3ded1a740ed2bad267a2a5529da44743c8d29b31b91604')
+
+prepare() {
+    chmod +x "${_appimage}"
+    ./"${_appimage}" --appimage-extract
+}
+
+build() {
+    # Adjust .desktop so it will work outside of AppImage container
+    sed -i -E "s|Exec=AppRun|Exec=env DESKTOPINTEGRATION=false /usr/bin/${_pkgname}|"\
+        "squashfs-root/${_pkgname}.desktop"
+    # Fix permissions; .AppImage permissions are 700 for all directories
+    chmod -R a-x+rX squashfs-root/usr
+}
+
+package() {
+    # AppImage
+    install -Dm755 "${srcdir}/${_appimage}" "${pkgdir}/opt/${pkgname}/${pkgname}.AppImage"
+
+    # Desktop file
+    install -Dm644 "${srcdir}/squashfs-root/${_pkgname}.desktop"\
+            "${pkgdir}/usr/share/applications/${_pkgname}.desktop"
+
+    # Icon images
+    install -dm755 "${pkgdir}/usr/share/"
+    cp -a "${srcdir}/squashfs-root/usr/share/icons" "${pkgdir}/usr/share/"
+
+    # Symlink executable
+    install -dm755 "${pkgdir}/usr/bin"
+    ln -s "/opt/${pkgname}/${pkgname}.AppImage" "${pkgdir}/usr/bin/${_pkgname}"
+}
+