package cleanup

2 files changed, 34 insertions, 19 deletions

diff --git a/.SRCINFO b/.SRCINFO
index a6ad1d65f389..2b63cd7176a4 100644
--- a/.SRCINFO
+++ b/.SRCINFO
@@ -1,13 +1,17 @@
 pkgbase = python-pocket
-	pkgdesc = api wrapper for getpocket.com
+	pkgdesc = API wrapper for getpocket.com
 	pkgver = 0.3.7
-	pkgrel = 1
+	pkgrel = 2
 	url = https://github.com/tapanpandita/pocket
 	arch = any
 	license = BSD
+	checkdepends = python-mock
 	makedepends = python-setuptools
-	depends = python
-	source = pocket-0.3.7.tar.gz::https://github.com/tapanpandita/pocket/archive/v0.3.7.tar.gz
-	sha512sums = d6b320c40baabcf4cb6b7c7557a3ecc07b997905336010bc5cb061263b0c6f79d13d9fc51f2c070859f2f1acd85d5508b29eb755538a711b9885b1cee8329d10
+	makedepends = python-build
+	makedepends = python-installer
+	makedepends = python-wheel
+	depends = python-requests
+	source = python-pocket-0.3.7.tar.gz::https://github.com/tapanpandita/pocket/archive/v0.3.7.tar.gz
+	sha256sums = 43af3e06769bb6b65f2145802fdaf60e92b34135813f2b01c3e736d89d90d22f
 
 pkgname = python-pocket
diff --git a/PKGBUILD b/PKGBUILD
index 999d7f6b9b34..7ebc6f2e5d23 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,28 +1,39 @@
-# Maintainer: Daniel Moch <daniel AT danielmoch DOT com>
+# Maintainer: Luis Martinez <luis dot martinez at disroot dot org>
+# Contributor: Daniel Moch <daniel AT danielmoch DOT com>
 # Contributor: Greg Fitzgerald <gregf@hugops.pw>
 
 pkgname=python-pocket
-_name=${pkgname#python-}
+_pkg=${pkgname#python-}
 pkgver=0.3.7
-pkgrel=1
-pkgdesc="api wrapper for getpocket.com"
-url="https://github.com/tapanpandita/${_name}"
+pkgrel=2
+pkgdesc="API wrapper for getpocket.com"
+url='https://github.com/tapanpandita/pocket'
 license=('BSD')
 arch=('any')
-depends=('python')
-makedepends=('python-setuptools')
-source=("${_name}-${pkgver}.tar.gz::https://github.com/tapanpandita/pocket/archive/v${pkgver}.tar.gz")
-sha512sums=('d6b320c40baabcf4cb6b7c7557a3ecc07b997905336010bc5cb061263b0c6f79d13d9fc51f2c070859f2f1acd85d5508b29eb755538a711b9885b1cee8329d10')
+depends=('python-requests')
+makedepends=('python-setuptools' 'python-build' 'python-installer' 'python-wheel')
+checkdepends=('python-mock')
+source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
+sha256sums=('43af3e06769bb6b65f2145802fdaf60e92b34135813f2b01c3e736d89d90d22f')
 
 build() {
-  cd "${srcdir}/${_name}-${pkgver}"
-  python setup.py build
+  cd "$_pkg-$pkgver"
+  python -m build --wheel --no-isolation
+}
+
+check() {
+  cd "$_pkg-$pkgver"
+  python -m unittest test_pocket.py
 }
 
 package() {
-  cd "$srcdir/${_name}-${pkgver}/"
-  install -Dm644 LICENSE.md "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
-  python setup.py install --root="${pkgdir}/" --optimize=1
+  cd "$_pkg-$pkgver"
+  PYTHONHASHSEED=0 python -m installer --destdir="$pkgdir/" dist/*.whl
+  local _site="$(python -c 'import site; print(site.getsitepackages()[0])')"
+  install -d "$pkgdir/usr/share/licenses/$pkgname/"
+  ln -s \
+    "$_site/$_pkg-$pkgver.dist-info/LICENSE.md" \
+    "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
 }
 
 # vim: sts=2 sw=2 et ft=PKGBUILD