update to build both qt5 and qt6 versions of the package

2 files changed, 50 insertions, 33 deletions

diff --git a/.SRCINFO b/.SRCINFO
index 4836669583fe..d3f87e6c7a55 100644
--- a/.SRCINFO
+++ b/.SRCINFO
@@ -1,6 +1,6 @@
 pkgbase = adwaita-qt-git
-	pkgdesc = A style to bend Qt applications to look like they belong into GNOME Shell (Qt5).
-	pkgver = 1.3.0.r3.g1a089c8
+	pkgdesc = A style to bend Qt applications to look like they belong into GNOME Shell, git package.
+	pkgver = 1.4.1.r17.g417df19
 	pkgrel = 1
 	url = https://github.com/FedoraQt/adwaita-qt
 	arch = x86_64
@@ -8,15 +8,20 @@ pkgbase = adwaita-qt-git
 	makedepends = cmake
 	makedepends = git
 	makedepends = qt5-x11extras
+	makedepends = qt6-base
+	source = adwaita-qt::git+https://github.com/FedoraQt/adwaita-qt.git
+	sha512sums = SKIP
+
+pkgname = adwaita-qt5-git
+	pkgdesc = A style to bend Qt5 applications to look like they belong into GNOME Shell, git version
 	depends = qt5-base
-	optdepends = qgnomeplatform: apply GNOME settings to Qt apps
-	provides = adwaita-qt-common
-	provides = adwaita-qt
+	optdepends = qt5-x11extras: For X11 and/or xwayland support
 	provides = adwaita-qt5
-	conflicts = adwaita-qt-common
 	conflicts = adwaita-qt
 	conflicts = adwaita-qt5
-	source = adwaita-qt::git+https://github.com/FedoraQt/adwaita-qt.git
-	sha512sums = SKIP
 
-pkgname = adwaita-qt-git
+pkgname = adwaita-qt6-git
+	pkgdesc = A style to bend Qt6 applications to look like they belong into GNOME Shell, git version
+	depends = qt6-base
+	provides = adwaita-qt6
+	conflicts = adwaita-qt6
diff --git a/PKGBUILD b/PKGBUILD
index 41845f2e7674..47c99113510d 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,38 +1,50 @@
 # Maintainer: Taijian <taijian@posteo.de>
 # Contributor: Mohammadreza Abdollahzadeh <morealaz at gmail dot com>
 
-pkgname=adwaita-qt-git
-pkgver=1.3.0.r3.g1a089c8
+pkgbase=adwaita-qt-git
+pkgname=(adwaita-qt5-git adwaita-qt6-git)
+pkgver=1.4.1.r17.g417df19
 pkgrel=1
-pkgdesc='A style to bend Qt applications to look like they belong into GNOME Shell (Qt5).'
-arch=('x86_64')
-url="https://github.com/FedoraQt/adwaita-qt"
-license=('GPL')
-depends=('qt5-base')
-makedepends=('cmake' 'git' 'qt5-x11extras')
-optdepends=('qgnomeplatform: apply GNOME settings to Qt apps')
-conflicts=('adwaita-qt-common' "${pkgname%-git}" 'adwaita-qt5')
-provides=('adwaita-qt-common' "${pkgname%-git}" 'adwaita-qt5')
-source=("${pkgname%-git}::git+${url}.git")
+pkgdesc='A style to bend Qt applications to look like they belong into GNOME Shell, git package.'
+arch=(x86_64)
+url='https://github.com/FedoraQt/adwaita-qt'
+license=(GPL)
+makedepends=(cmake git qt5-x11extras qt6-base)
+source=("${pkgbase%-git}::git+${url}.git")
 sha512sums=('SKIP')
 
 pkgver() {
-    cd "${pkgname%-git}"
+    cd "${pkgbase%-git}"
     git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
 }
 
 build() {
-    cd "${pkgname%-git}"
-    mkdir build
-    cd build
-    cmake .. \
-        -DCMAKE_BUILD_TYPE=Release \
-        -DCMAKE_INSTALL_PREFIX=/usr
-    make
+  cmake -B build-qt5 -S ${pkgbase%-git} \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DUSE_QT6=OFF
+  cmake --build build-qt5
+
+  cmake -B build-qt6 -S ${pkgbase%-git} \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DUSE_QT6=ON
+  cmake --build build-qt6
 }
 
-package() {
-    cd "${pkgname%-git}/build"
-    make DESTDIR="$pkgdir" install
-    install -Dm644 -t "${pkgdir}/usr/share/doc/${pkgname}" ../README.md
+package_adwaita-qt5-git() {
+  pkgdesc='A style to bend Qt5 applications to look like they belong into GNOME Shell, git version'
+  depends=(qt5-base)
+  optdepends=('qt5-x11extras: For X11 and/or xwayland support')
+  conflicts=(adwaita-qt adwaita-qt5)
+  provides=(adwaita-qt5)
+
+  DESTDIR="$pkgdir" cmake --install build-qt5
+}
+
+package_adwaita-qt6-git() {
+  pkgdesc='A style to bend Qt6 applications to look like they belong into GNOME Shell, git version'
+  depends=(qt6-base)
+  conflicts=(adwaita-qt6)
+  provides=(adwaita-qt6)
+
+  DESTDIR="$pkgdir" cmake --install build-qt6
 }