Initial commit

2 files changed, 51 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..e1e51dfa3627
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,16 @@
+pkgbase = cs-string-git
+	pkgdesc = Standalone library for unicode aware string support (git version)
+	pkgver = r45.c6f1f51
+	pkgrel = 1
+	url = https://www.copperspice.com/
+	arch = x86_64
+	license = BSD
+	makedepends = git
+	makedepends = cmake
+	provides = cs-string
+	conflicts = cs-string
+	source = git+https://github.com/copperspice/cs_string.git
+	sha256sums = SKIP
+
+pkgname = cs-string-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..3b118cae8ef5
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,35 @@
+# Maintainer: Daniel Bermond <dbermond@archlinux.org>
+
+pkgname=cs-string-git
+pkgver=r45.c6f1f51
+pkgrel=1
+pkgdesc='Standalone library for unicode aware string support (git version)'
+arch=('x86_64')
+url='https://www.copperspice.com/'
+license=('BSD')
+makedepends=('git' 'cmake')
+provides=('cs-string')
+conflicts=('cs-string')
+source=('git+https://github.com/copperspice/cs_string.git')
+sha256sums=('SKIP')
+
+pkgver() {
+    printf 'r%s.%s' "$(git -C cs_string rev-list --count HEAD)" "$(git -C cs_string rev-parse --short HEAD)"
+}
+
+build() {
+    cmake -B build -S cs_string \
+        -DCMAKE_BUILD_TYPE:STRING='None' \
+        -DCMAKE_INSTALL_PREFIX:PATH='/usr' \
+        -Wno-dev
+    make -C build
+}
+
+check() {
+    build/bin/Test
+}
+
+package() {
+    make -C build DESTDIR="$pkgdir" install
+    install -D -m644 cs_string/LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
+}