Add .SRCINFO and PKGBUILD

1 files changed, 37 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..c553219535be
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,37 @@
+# Maintainer: Ben Silverman <bensilverman10 at gmail dot com>
+_npmname=alacritty-themes
+pkgname=${_npmname}
+pkgver=2.0.2
+pkgrel=1
+pkgdesc="A utility for choosing and applying Alacritty terminal themes."
+arch=(any)
+url="https://github.com/rajasegar/alacritty-themes"
+license=("MIT")
+depends=("nodejs")
+makedepends=("npm" "jq")
+source=("https://registry.npmjs.org/${_npmname}/-/${_npmname}-${pkgver}.tgz")
+noextract=("${pkgname}-${pkgver}.tgz")
+md5sums=('3d94583d23aaccba842956e25454fd92')
+
+package() {
+    npm install -g --cache "${srcdir}/npm-cache" --user root --prefix "${pkgdir}/usr" "${srcdir}/${pkgname}-${pkgver}.tgz"
+
+    # Non-deterministic race in npm gives 777 permissions to random directories.
+    # See https://github.com/npm/cli/issues/1103 for details.
+    find "${pkgdir}/usr" -type d -exec chmod 755 {} +
+
+    # npm gives ownership of ALL FILES to build user
+    # https://bugs.archlinux.org/task/63396
+    chown -R root:root "${pkgdir}"
+    
+    # Remove references to $pkgdir
+    find "$pkgdir" -name package.json -print0 | xargs -r -0 sed -i '/_where/d'
+
+    # Remove references to $srcdir
+    local tmppackage="$(mktemp)"
+    local pkgjson="$pkgdir/usr/lib/node_modules/$pkgname/package.json"
+    jq '.|=with_entries(select(.key|test("_.+")|not))' "$pkgjson" > "$tmppackage"
+    mv "$tmppackage" "$pkgjson"
+    chmod 644 "$pkgjson"
+}
+