Initial import; Qt 6.0.0

1 files changed, 51 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..15f71d48ccb1
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,51 @@
+# Maintainer: Martchus <martchus@gmx.net>
+
+# All my PKGBUILDs are managed at https://github.com/Martchus/PKGBUILDs where
+# you also find the URL of a binary repository.
+
+_android_arch=aarch64
+pkgname=android-$_android_arch-qt6-quick3d
+_qtver=6.0.0
+pkgver=${_qtver/-/}
+pkgrel=1
+arch=(any)
+url='https://www.qt.io'
+license=(GPL3 LGPL3 FDL custom)
+pkgdesc='Qt module and API for defining 3D content in Qt Quick (android)'
+depends=('android-aarch64-qt6-declarative')
+makedepends=('android-cmake' 'android-aarch64-qt6-shadertools' 'qt6-quick3d' 'qt6-shadertools' 'ninja' 'java-environment-openjdk=8')
+options=('!strip' '!buildflags' 'staticlibs' '!emptydirs')
+groups=(android-${_android_arch}-qt6)
+_pkgfqn="qtquick3d-everywhere-src-${_qtver}"
+source=("https://download.qt.io/official_releases/qt/${pkgver%.*}/${_qtver}/submodules/${_pkgfqn}.tar.xz")
+sha256sums=('0a9a3e765c343b55511900b173f9591df88b0787f67b9ecfb8f25203bfdb0aa8')
+
+build() {
+  source android-env ${_android_arch}
+  android-${_android_arch}-cmake -G Ninja -B build-$_android_arch -S $_pkgfqn \
+    -DCMAKE_FIND_ROOT_PATH="${ANDROID_PREFIX}" \
+    -DQT_BINARY_DIR=${ANDROID_PREFIX_BIN} \
+    -DQT_INCLUDE_DIRS_NO_SYSTEM=ON \
+    -DQT_HOST_PATH=/usr \
+    -DANDROID_SDK_ROOT=${ANDROID_HOME} \
+    -DANDROID_NDK_ROOT=${ANDROID_NDK_HOME} \
+    -DANDROID_STL="c++_shared" \
+    -DFEATURE_pkg_config=ON
+  cmake --build build-$_android_arch
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build-$_android_arch
+
+  # Drop QMAKE_PRL_BUILD_DIR because reference the build dir
+  find "$pkgdir/${ANDROID_PREFIX}" -type f -name '*.prl' \
+    -exec sed -i -e '/^QMAKE_PRL_BUILD_DIR/d' {} \;
+
+  find ${pkgdir}/${ANDROID_PREFIX} -type f -name 'lib*.so' -exec ${ANDROID_STRIP} -g --strip-unneeded {} \;
+  find ${pkgdir}/${ANDROID_PREFIX} -type f -name 'lib*.a' -exec ${ANDROID_STRIP} -g {} \;
+  [[ -d "${pkgdir}/${ANDROID_PREFIX}/share/doc" ]] && rm -r "${pkgdir}/${ANDROID_PREFIX}/share/doc" || true
+
+  install -d "$pkgdir"/usr/share/licenses
+  ln -s /usr/share/licenses/android-$_android_arch-qt6-base "$pkgdir"/usr/share/licenses/$pkgname
+
+}