revision

1 files changed, 57 insertions, 26 deletions

diff --git a/PKGBUILD b/PKGBUILD
index 6bfcfd6c7eb3..7b9740f97142 100755
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,43 +1,74 @@
+# Maintainer: Fabio 'Lolix' Loli <lolix@disroot.org>
+# Contributor: Glaucous <glakke1 at gmail dot com>
 # Contributor: Luca Bennati <lucak3 AT gmail DOT com>
-# Maintainer: Glaucous <glakke1 at gmail dot com>
 
 pkgname=apitrace-git
-pkgver=3598.cfa80d0
+pkgver=11.1.r102.g9de54e55
 pkgrel=1
 pkgdesc="Graphics API Tracing"
-arch=('x86_64' 'i686')
+arch=(x86_64)
 url="https://github.com/apitrace/apitrace"
-license=('BSD')
-makedepends=('cmake>=2.8' 'git' 'mesa' 'qt5-webkit')
-depends=('python2' 'libgl' 'procps-ng')
-optdepends=('qt5-webkit: GUI support')
-provides=('apitrace')
-conflicts=('apitrace')
-source=('apitrace::git+http://github.com/apitrace/apitrace.git#branch=master')
-md5sums=(SKIP)
+license=(BSD)
+depends=(qt6-base python-pillow python-numpy libgl procps-ng)
+makedepends=(cmake git mesa)
+provides=(apitrace)
+conflicts=(apitrace)
+source=("git+https://github.com/apitrace/apitrace.git"
+        "git+https://github.com/apitrace/gltrim-tests.git"
+        "git+https://github.com/google/brotli.git"
+        "git+https://github.com/google/googletest.git"
+        "git+https://github.com/ianlancetaylor/libbacktrace.git"
+        "apitrace-libpng::git+https://github.com/apitrace/libpng.git"
+        "git+https://github.com/google/snappy.git"
+        "git+https://github.com/madler/zlib.git"
+        "git+https://github.com/microsoft/DirectXMath.git"
+        )
+sha256sums=('SKIP'
+            'SKIP'
+            'SKIP'
+            'SKIP'
+            'SKIP'
+            'SKIP'
+            'SKIP'
+            'SKIP'
+            'SKIP')
 
-pkgver() {
-  cd ${srcdir}/apitrace
+prepare() {
+  cd apitrace
+  git submodule init
+  git config submodule.frametrim/tests.url          "${srcdir}/gltrim-tests"
+  git config submodule.thirdparty/brotli.url        "${srcdir}/brotli"
+  git config submodule.thirdparty/gtest.url         "${srcdir}/googletest"
+  git config submodule.thirdparty/libbacktrace.url  "${srcdir}/libbacktrace"
+  git config submodule.thirdparty/libpng.url        "${srcdir}/apitrace-libpng"
+  git config submodule.thirdparty/snappy.url        "${srcdir}/snappy"
+  git config submodule.thirdparty/zlib.url          "${srcdir}/zlib"
+  git config submodule.thirdparty/directxmath.url   "${srcdir}/DirectXMath"
+  git -c protocol.file.allow=always submodule update
+}
 
-  echo $(git rev-list --count master).$(git rev-parse --short master)
+pkgver() {
+  cd apitrace
+  git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
 }
 
 build() {
-  cd ${srcdir}/apitrace
-
-  cmake . -Bbuild -DCMAKE_INSTALL_PREFIX=/usr \
-    -DPYTHON_EXECUTABLE=/usr/bin/python2.7 \
+  cd apitrace
+  cmake . -Bbuild \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DENABLE_QT6=TRUE \
+    -DENABLE_GUI=TESTS \
     -DENABLE_GUI=TRUE
   make -C build
 }
 
-package() {
-  cd ${srcdir}/apitrace
-  make -C build DESTDIR="${pkgdir}/" install
-
-  mkdir -p "${pkgdir}"/usr/share/licenses/apitrace-git
-  cd "${pkgdir}"/usr/share/licenses/apitrace-git
-  ln -s ../../doc/apitrace/LICENSE.txt LICENSE
+check() {
+  cd apitrace
+  make -C build test
 }
 
-# vim:set ts=2 sw=2 et:
+package() {
+  cd apitrace
+  make -C build DESTDIR="${pkgdir}/" install
+  install -D LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
+}
\ No newline at end of file