initial commit

1 files changed, 38 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..2c20c3d61354
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,38 @@
+# Maintainer: Luis Martinez <luis dot martinez at disroot dot org>
+
+pkgname=apollo-rover
+pkgver=0.3.0
+pkgrel=1
+pkgdesc="CLI for Apollo's suite of GraphQL developer productivity tools"
+arch=('x86_64')
+url='https://github.com/apollographql/rover'
+license=('MIT')
+depends=('gcc-libs' 'zlib')
+makedepends=('cargo')
+source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
+sha256sums=('1ba8ef546cfef89517a8ee9932aae683cab523d212ea8d3d4fe1359a15aa3be6')
+
+prepare() {
+	cd "rover-$pkgver"
+	cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
+}
+
+build() {
+	export RUSTUP_TOOLCHAIN=stable
+	export CARGO_TARGET_DIR=target
+	cd "rover-$pkgver"
+	cargo build --frozen --release --all-features
+}
+
+check() {
+	export RUSTUP_TOOLCHAIN=stable
+	cd "rover-$pkgver"
+	cargo test --frozen --all-features
+}
+
+package() {
+	cd "rover-$pkgver"
+	install -D "target/release/rover" -t "$pkgdir/usr/bin/"
+	install -Dm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
+	install -Dm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname/"
+}