Initial commit

1 files changed, 51 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..c46e2832bc48
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,51 @@
+# Maintainer: Charles Milette <charles.milette@gmail.com>
+# Originally taken from https://www.archlinux.org/packages/community/any/arc-gtk-theme/
+
+pkgbase=arc-orange-gtk-theme-git
+_pkgname=arc-theme-orange
+pkgname=('arc-orange-gtk-theme-git' 'arc-orange-solid-gtk-theme-git')
+pkgver=r57.af13f6a
+pkgrel=1
+arch=('any')
+url="https://github.com/eti0/${_pkgname}"
+license=('GPL3')
+optdepends=('arc-icon-theme: recommended icon theme'
+            'gtk-engine-murrine: for gtk2 themes'
+            'gnome-themes-standard: for gtk2 themes')
+makedepends=('gtk3')
+source=("git+https://github.com/eti0/${_pkgname}.git"
+        'change-solid-theme-path.patch')
+sha512sums=('SKIP'
+            '5b1ca739206e386cb4bf1f2f0a9524a08f2590972126cc96ef7c2e56ca59e94136cf7f8dc8184cd1c688a488e5e96384d654e279778f93e8f34860f7281afff9')
+pkgver() {
+	cd "${srcdir}/${_pkgname}"
+	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+prepare() {
+    cp -a ${_pkgname}{,-solid}
+    cd ${_pkgname}-solid
+    patch -p1 -i ../change-solid-theme-path.patch
+}
+
+build() {
+    cd ${_pkgname}
+    ./autogen.sh --prefix=/usr
+
+    cd ../${_pkgname}-solid
+    ./autogen.sh --prefix=/usr --disable-transparency
+}
+
+package_arc-orange-gtk-theme-git() {
+    pkgdesc="A flat theme with transparent elements for GTK 3, GTK 2 and Gnome-Shell"
+
+    cd ${_pkgname}
+    make DESTDIR="${pkgdir}" install
+}
+
+package_arc-orange-solid-gtk-theme-git() {
+    pkgdesc="A flat theme for GTK 3, GTK 2 and Gnome-Shell (without transparency)"
+
+    cd ${_pkgname}-solid
+    make DESTDIR="${pkgdir}" install
+}