Initial commit.

1 files changed, 68 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..f74b6cf0a42d
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,68 @@
+# Maintainer: twa022 <twa022 at gmail dot com>
+
+_pkgname=audacious-plugins
+pkgname=${_pkgname}-qt5
+pkgver=3.7
+pkgrel=1
+pkgdesc="Plugins for Audacious (qt5 interface)"
+arch=('i686' 'x86_64')
+url="http://audacious-media-player.org/"
+license=('BSD' 'GPL')
+
+makedepends=("audacious-qt5>=$pkgver" 'qt5-multimedia'
+             'glib2' 'python2' # for gdbus-codegen
+             'alsa-lib' 'pulseaudio' 'jack2' 'lame' 'libvorbis' 'flac'
+             'mpg123' 'faad2' 'ffmpeg' 'libmodplug' 'fluidsynth' 'libcdio-paranoia' 'libsidplayfp' 'wavpack'
+             'dbus-glib' 'libnotify' 'lirc' 'curl' 'libmtp'
+             'neon' 'libmms' 'libcue')
+
+optdepends=('alsa-lib: Advanced Linux Sound Arch. output'
+            'pulseaudio: PulseAudio output'
+            'jack2: Jack Audio Connection Kit output'
+            'lame: FileWriter MP3 output'
+            'libvorbis: Vorbis input, FileWriter Vorbis output'
+            'flac: FLAC input, FileWriter FLAC output'
+
+            'mpg123: MP3 input'
+            'faad2: AAC input'
+            'ffmpeg: ffaudio input'
+            'libmodplug: modplug input'
+            'fluidsynth: MIDI FluidSynth backend input'
+            'libcdio-paranoia: CD Digital Audio input'
+            'libsidplayfp: Commodore 64 audio input'
+            'wavpack: WavPack input'
+
+            'dbus-glib: Gnome Shortcuts Plugin'
+            'libnotify: libnotify OSD'
+            'lirc: LIRC'
+            'curl: AudioScrobbler Client'
+            'libmtp: Upload to MTP device'
+
+            'neon: neon-based http transport'
+            'libmms: libmms-based mms transport'
+            'libcue: CUE playlist format'
+
+            'qt5-multimedia: qtaudio support')
+
+provides=("${_pkgname}=${pkgver}")
+conflicts=("${_pkgname}")
+source=(http://distfiles.audacious-media-player.org/$_pkgname-$pkgver.tar.bz2)
+sha256sums=('3856e9f7261cbb27b5e15246ee3959189ab950389ef02aaec27d645a0a516c2c')
+
+build() {
+  cd "$srcdir/$_pkgname-$pkgver"
+
+  ./configure \
+    --prefix=/usr \
+    --enable-amidiplug \
+    --disable-adplug \
+    --enable-qt \
+    --disable-gtk
+  make
+}
+
+package() {
+  cd "$srcdir/$_pkgname-$pkgver"
+  make DESTDIR="$pkgdir" install
+  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$_pkgname/LICENSE"
+}