Initial import

1 files changed, 62 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..719c312698af
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,62 @@
+# Maintainer: Colin Woodbury <colingw@gmail.com>
+_hkgname=aura
+pkgname=aura
+pkgver=1.3.0.5
+pkgrel=1
+pkgdesc="A secure package manager for Arch Linux and the AUR written in Haskell."
+url="https://github.com/fosskers/aura"
+license=('GPL-3')
+arch=('i686' 'x86_64')
+depends=('gmp' 'pacman' 'pcre' 'abs')
+makedepends=('ghc'
+             'haskell-aur'
+             'haskell-lens'
+             'haskell-mtl'
+             'haskell-parsec'
+             'haskell-regex-base'
+             'haskell-regex-pcre-builtin'
+             'haskell-split'
+             'haskell-temporary'
+             'haskell-text'
+             'haskell-transformers'
+             'haskell-wreq>=0.3')
+optdepends=('powerpill:    For faster repository downloads.'
+            'customizepkg: For auto-editing of PKGBUILDs.'
+            'aur-git:      AUR package completions for zsh.')
+provides=('aura')
+conflicts=('aura-git' 'aura-bin')
+options=('strip')
+source=(https://bitbucket.org/fosskers/aura/downloads/${_hkgname}-${pkgver}.tar.gz)
+md5sums=('eddedac8a9c144ee916fa4ada64485b6')
+
+build() {
+    cd ${srcdir}/${_hkgname}-${pkgver}
+    runhaskell Setup configure --prefix=/usr --docdir=/usr/share/doc/${pkgname} -O
+    runhaskell Setup build
+}
+
+package() {
+    cd ${srcdir}/${_hkgname}-${pkgver}
+    runhaskell Setup copy --destdir=${pkgdir}
+
+    # Installing man page
+    mkdir -p "$pkgdir/usr/share/man/man8/"
+    install -m 644 doc/aura.8 "$pkgdir/usr/share/man/man8/aura.8"
+
+    # Installing bash completions
+    mkdir -p "$pkgdir/usr/share/bash-completion/completions/"
+    install -m 644 doc/completions/bashcompletion.sh "$pkgdir/usr/share/bash-completion/completions/aura"
+
+    # Installing zsh completions
+    mkdir -p "$pkgdir/usr/share/zsh/site-functions/"
+    install -m 644 doc/completions/_aura "$pkgdir/usr/share/zsh/site-functions/_aura"
+
+    # Directory for storing PKGBUILDs
+    mkdir -p "$pkgdir/var/cache/aura/pkgbuilds"
+
+    # Directory for storing source packages
+    mkdir -p "$pkgdir/var/cache/aura/src"
+
+    # Directory for storing installed package states
+    mkdir -p "$pkgdir/var/cache/aura/states"
+}