3.1.4-2

1 files changed, 15 insertions, 25 deletions

diff --git a/PKGBUILD b/PKGBUILD
index 593d9b13c560..6585a119b010 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,49 +1,39 @@
 # Maintainer: Colin Woodbury <colin@fosskers.ca>
 pkgname=aura-bin
 pkgver=3.1.4
-pkgrel=1
+pkgrel=2
 pkgdesc="A secure package manager for Arch Linux and the AUR - Prebuilt binary"
 url="https://github.com/fosskers/aura"
-license=('GPL-3')
+license=('GPL3')
 arch=('x86_64')
 depends=('gmp' 'pacman' 'git')
-optdepends=()
+optdepends=('bash-completion: for bash completions')
 provides=('aura')
 conflicts=('aura' 'aura-git')
 options=('strip')
 backup=("etc/aura.conf")
-source=(https://github.com/fosskers/aura/releases/download/v${pkgver}/aura-${pkgver}-x86_64.tar.gz)
-md5sums=('a1f2b5e51d780b0d7a9f7178e7c48637')
+source=("$pkgname-$pkgver.tar.gz::$url/releases/download/v$pkgver/aura-$pkgver-x86_64.tar.gz")
+sha256sums=('3990075162176eeea076c9ca1f75531681607f68a3a77e6b2c24652c7674ae4e')
 
 package() {
     # Install aura binary
-    mkdir -p "$pkgdir/usr/bin/"
-    install -m 755 aura "$pkgdir/usr/bin/"
+    install -Dm755 aura -t "$pkgdir/usr/bin/"
 
     # Installing conf file
-    mkdir -p "$pkgdir/etc/"
-    install -m 644 aura.conf "$pkgdir/etc/aura.conf"
+    install -Dm644 aura.conf -t "$pkgdir/etc"
 
     # Installing man pages
-    mkdir -p "$pkgdir/usr/share/man/man8/"
-    install -m 644 aura.8 "$pkgdir/usr/share/man/man8/aura.8"
-    mkdir -p "$pkgdir/usr/share/man/man5/"
-    install -m 644 aura.conf.5 "$pkgdir/usr/share/man/man5/aura.conf.5"
+    install -Dm644 aura.8 -t "$pkgdir/usr/share/man/man8"
+    install -Dm644 aura.conf.5 -t "$pkgdir/usr/share/man/man5"
 
     # Installing bash completions
-    mkdir -p "$pkgdir/usr/share/bash-completion/completions/"
-    install -m 644 bashcompletion.sh "$pkgdir/usr/share/bash-completion/completions/aura"
+    install -Dm644 bashcompletion.sh \
+      "$pkgdir/usr/share/bash-completion/completions/$pkgname"
 
     # Installing zsh completions
-    mkdir -p "$pkgdir/usr/share/zsh/site-functions/"
-    install -m 644 _aura "$pkgdir/usr/share/zsh/site-functions/_aura"
+    install -Dm644 _aura -t \
+      "$pkgdir/usr/share/zsh/site-functions"
 
-    # Directory for storing PKGBUILDs
-    mkdir -p "$pkgdir/var/cache/aura/pkgbuilds"
-
-    # Directory for storing source packages
-    mkdir -p "$pkgdir/var/cache/aura/src"
-
-    # Directory for storing installed package states
-    mkdir -p "$pkgdir/var/cache/aura/states"
+    # Directories for storing PKGBUILDs, source packages & installed package states
+    install -d "$pkgdir/var/cache/$pkgname/"{pkgbuilds,src,states}
 }