New package 'avbin'

1 files changed, 43 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..7fb3159469ca
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,43 @@
+# Maintainer: Christopher Arndt <aur -at- chrisarndt -dot- de>
+
+pkgname=avbin
+pkgver=10
+pkgrel=1
+_gittag="$pkgname-$pkgver"
+pkgdesc="Cross-platform media decoding library"
+arch=('i686' 'x86_64')
+url="http://avbin.github.com/"
+license=('LGPL')
+depends=('bzip2' 'zlib')
+conflicts=('avbin7')
+makedepends=('git' 'yasm')
+options=('!makeflags')
+# The build script relies on being run in a git checkout,
+# the downloadable release tarball doesn't work with it
+source=("${pkgname}::git+https://github.com/AVbin/AVbin.git")
+sha256sums=('SKIP')
+
+prepare() {
+    cd "${srcdir}/${pkgname}"
+
+    git checkout "${_gittag}"
+}
+
+build() {
+    cd "${srcdir}/${pkgname}"
+
+    target="linux-$(echo $CARCH | sed -e 's/_/-/')"
+    msg "Building target ${target}..."
+    # Linux Makefile uses LDFLAGS directly for ld command line
+    export LDFLAGS="$(echo $LDFLAGS | sed -e 's/^-Wl//')"
+    ./build.sh --fast ${target}
+}
+
+package() {
+    cd "${srcdir}/${pkgname}"
+
+    target="linux-$(echo $CARCH | sed -e 's/_/-/')"
+    install -dm755 "$pkgdir/usr/lib"
+    install -m644 "dist/${target}/libavbin.so.${pkgver}" "$pkgdir/usr/lib"
+    ln -sf "libavbin.so.${pkgver}" "$pkgdir/usr/lib/libavbin.so"
+}