summarylogtreecommitdiffstats
path: root/PKGBUILD
diff options
context:
space:
mode:
authorFabien2020-11-06 21:28:03 +0100
committerFabien2020-11-06 21:28:37 +0100
commit86fc6b181de1469e38778c6bca31acdb724eab6e (patch)
treeaef3ba1d14eb4ae04693125ac448da551fb0f156 /PKGBUILD
downloadaur-86fc6b181de1469e38778c6bca31acdb724eab6e.tar.gz
Initial version
Diffstat (limited to 'PKGBUILD')
-rw-r--r--PKGBUILD107
1 files changed, 107 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 00000000000..1e8e32abe7a
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,107 @@
+# Maintainer: Fabien <fabcien@gmail.com>
+# Contributor: Josh Ellithorpe <quest@mac.com>
+
+pkgname=bitcoin-abc-bchn
+pkgver=0.22.6
+pkgrel=0
+pkgdesc="Bitcoin ABC (BCHN network) with bitcoind, bitcoin-tx, bitcoin-seeder and bitcoin-cli"
+arch=('i686' 'x86_64')
+url="https://bitcoinabc.org"
+depends=('boost-libs' 'libevent' 'openssl' 'zeromq' 'miniupnpc' 'jemalloc')
+makedepends=('cmake' 'ninja' 'boost' 'python' 'help2man')
+license=('MIT')
+source=(https://github.com/Bitcoin-ABC/bitcoin-abc/archive/v$pkgver.tar.gz
+ bitcoin.conf
+ bitcoin.logrotate
+ bitcoin.service
+ bitcoin-reindex.service
+ bitcoin.install)
+backup=('etc/bitcoin/bitcoin.conf'
+ 'etc/logrotate.d/bitcoin')
+provides=('bitcoin-cli' 'bitcoin-daemon' 'bitcoin-tx' 'bitcoin-seeder')
+conflicts=('bitcoin-cli' 'bitcoin-daemon' 'bitcoin-tx' 'bitcoin-seeder')
+install=bitcoin.install
+
+build() {
+ cd "$srcdir/bitcoin-abc-$pkgver"
+
+ msg2 'Building...'
+ mkdir -p build
+ pushd build
+
+ cmake -GNinja .. \
+ -DENABLE_CLANG_TIDY=OFF \
+ -DCLIENT_VERSION_IS_RELEASE=ON \
+ -DENABLE_REDUCE_EXPORTS=ON \
+ -DENABLE_STATIC_LIBSTDCXX=ON \
+ -DBUILD_BITCOIN_WALLET=OFF \
+ -DBUILD_BITCOIN_QT=OFF \
+ -DNETWORK_COMPATIBILITY=BCHN \
+ -DCMAKE_INSTALL_PREFIX=$pkgdir/usr
+
+ ninja
+ popd
+}
+
+check() {
+ cd "$srcdir/bitcoin-abc-$pkgver/build"
+
+ msg2 'Testing...'
+ ninja check
+}
+
+package() {
+ cd "$srcdir/bitcoin-abc-$pkgver"
+
+ msg2 'Installing license...'
+ install -Dm 644 COPYING -t "$pkgdir/usr/share/licenses/${pkgname}"
+
+ msg2 'Installing examples...'
+ install -Dm644 "contrib/debian/examples/bitcoin.conf" \
+ -t "$pkgdir/usr/share/doc/bitcoin/examples"
+
+ msg2 'Installing documentation...'
+ install -dm 755 "$pkgdir/usr/share/doc/bitcoin"
+ for _doc in \
+ $(find doc -maxdepth 1 -type f -name "*.md" -printf '%f\n') \
+ release-notes; do
+ cp -dpr --no-preserve=ownership "doc/$_doc" \
+ "$pkgdir/usr/share/doc/bitcoin/$_doc"
+ done
+
+ msg2 'Installing essential directories'
+ install -dm 700 "$pkgdir/etc/bitcoin"
+ install -dm 755 "$pkgdir/srv/bitcoin"
+ install -dm 755 "$pkgdir/run/bitcoin"
+
+ pushd build
+ msg2 'Installing executables...'
+ ninja install/strip
+
+ msg2 'Installing man pages...'
+ #ninja install-manpages
+ popd
+
+ msg2 'Installing bitcoin.conf...'
+ install -Dm 600 "$srcdir/bitcoin.conf" -t "$pkgdir/etc/bitcoin"
+
+ msg2 'Installing bitcoin.service...'
+ install -Dm 644 "$srcdir/bitcoin.service" -t "$pkgdir/usr/lib/systemd/system"
+ install -Dm 644 "$srcdir/bitcoin-reindex.service" \
+ -t "$pkgdir/usr/lib/systemd/system"
+
+ msg2 'Installing bitcoin.logrotate...'
+ install -Dm 644 "$srcdir/bitcoin.logrotate" "$pkgdir/etc/logrotate.d/bitcoin"
+
+ msg2 'Installing bash completion...'
+ for _compl in bitcoin-cli bitcoin-tx bitcoind; do
+ install -Dm 644 "contrib/${_compl}.bash-completion" \
+ "$pkgdir/usr/share/bash-completion/completions/$_compl"
+ done
+}
+sha256sums=('4ccb931c2f26046a69647b773037982dc6c8db056c8c89e6da0957b5e4dcd012'
+ 'c30e5c7e0e97b001fdeac5f4510d5ebc0e0499ec086325e845db609a24f2e22f'
+ '8f05207b586916d489b7d25a68eaacf6e678d7cbb5bfbac551903506b32f904f'
+ 'f2fd9d8331238727333cf2412ba3759cb194a65b2060eff36808b24c06382104'
+ '497dbeefb9cd9792757a9b6e1fbfd92710d19990ee2959add6c30533ae40b6f6'
+ '45429013dae87a58bc79ca7b7a037665bf8592cae0199bcf4aef088fb950e78a')