Various PKGBUILD improvements as for other B.* packages

Signed-off-by: Christopher Arndt <chris@chrisarndt.de>

1 files changed, 31 insertions, 35 deletions

diff --git a/PKGBUILD b/PKGBUILD
index 0d566ad74ab5..40a13787266f 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,52 +1,48 @@
 # Maintainer: Milk Brewster (milk on freenode irc)
-pkgname=bsequencer-git
-pkgver=r82.c4dd235
+# Contributor: Christopher Arndt <aur -at- chrisarndt -dot- de>
+
+_name="BSEQuencer"
+_pkgname="${_name,,}"
+_plugin_uri="https://www.jahnichen.de/plugins/lv2/${_name}"
+pkgname="${_pkgname}-git"
+pkgdesc="Multi channel MIDI step sequencer LV2 plugin (git version)"
+pkgver=1.8.0.r0.g8f96f92
 pkgrel=1
-epoch=
-pkgdesc="Multi channel MIDI step sequencer LV2 plugin."
 arch=('x86_64')
-url="https://github.com/sjaehn/BSEQuencer"
-license=('GPL')
-groups=()
-depends=('xorg-server' 'cairo' 'lv2')
-makedepends=()
-checkdepends=()
-optdepends=()
-provides=()
-conflicts=()
-replaces=()
-backup=()
-options=()
-install=
-changelog=
-source=("git+https://github.com/sjaehn/BSEQuencer")
-noextract=()
+url="https://github.com/sjaehn/${_name}"
+license=('GPL3')
+groups=('lv2-plugins' 'pro-audio')
+depends=('cairo' 'gcc-libs' 'glibc' 'libx11')
+makedepends=('git' 'lv2')
+checkdepends=('lv2lint')
+provides=("${_pkgname}" "${_pkgname}=${pkgver//.r*/}")
+conflicts=("${_pkgname}")
+source=("${_pkgname}::git+https://github.com/sjaehn/${_name}")
 md5sums=('SKIP')
-validpgpkeys=()
 
-# prepare() {
-# }
 
 pkgver() {
-  cd "$srcdir"/BSEQuencer
+  cd "${srcdir}/${_pkgname}"
   ( set -o pipefail
-    git describe --long 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
+    git describe --long --tags 2>/dev/null | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g' ||
     printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
   )
- }
-
+}
 
 build() {
-  cd "$srcdir"/BSEQuencer
+  cd "${srcdir}/${_pkgname}"
   make
 }
- 
-# check() {
-	# cd "$pkgname-$pkgver"
-	# make -k check
-# }
+
+check() {
+  cd "${srcdir}/${_pkgname}"
+  lv2lint -Mpack -I "${_name}.lv2/" "${_plugin_uri}"
+}
 
 package() {
-  cd "$srcdir"/BSEQuencer
-  make install PREFIX="${pkgdir}/usr/" install 
+  cd "${srcdir}/${_pkgname}"
+  make PREFIX="/usr" DESTDIR="$pkgdir/" install
+  install -vDm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
+  # remove useless license file
+  find "${pkgdir}/usr/lib/" -type f -iname "*LICENSE*" -delete
 }