Initial package upload

1 files changed, 44 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..a4ad4b61167e
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,44 @@
+# Maintainer: Kyle Laker <kyle+aur@laker.email>
+
+pkgname=chalice
+pkgver=1.22.1
+pkgrel=1
+pkgdesc="Python Serverless Microframework for AWS"
+arch=("any")
+url="https://github.com/aws/chalice"
+license=("Apache")
+depends=(\
+    "python"
+    "python-click"
+    "python-botocore"
+    "python-mypy_extensions"
+    "python-six"
+    "python-pip"
+    "python-attrs"
+    "python-jmespath"
+    "python-yaml"
+    "python-inquirer"
+    "python-wheel"
+    "python-setuptools"
+)
+makedepends=("python-setuptools" "mypy")
+optdepends=('python-watchdog: server auto-reload support'
+            'aws-cdk: AWS CDK support')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/aws/$pkgname/archive/$pkgver.tar.gz")
+sha512sums=('07e9f222b95d4ccae37b6e06537ad8171e9fa10a7781761367b7cdcf9689214b8c7ba59574ec4e16a3046c77c4e2f94bbef159bb0d4dbdfae2020afd89f663d6')
+
+prepare() {
+    cd "${srcdir}/$pkgname-$pkgver"
+    # Fix the tests getting included in the package
+    sed -i' ' -e "s/'tests'/'tests*'/" setup.py
+}
+
+build() {
+    cd "${srcdir}/${pkgname}-${pkgver}"
+    python setup.py build
+}
+
+package() {
+    cd "${srcdir}/${pkgname}-${pkgver}"
+    python setup.py install --skip-build --root="${pkgdir}" --optimize=1
+}